From d71aca7673826d5f5fa93b43c7c8af3c1e023dc6 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 12 Mar 2024 18:46:38 +0000
Subject: gentoo auto-resync : 12:03:2024 - 18:46:38

---
 dev-python/dask-expr/Manifest               |  3 ++
 dev-python/dask-expr/dask-expr-1.0.1.ebuild | 56 +++++++++++++++++++++++++++++
 dev-python/dask-expr/metadata.xml           | 12 +++++++
 3 files changed, 71 insertions(+)
 create mode 100644 dev-python/dask-expr/Manifest
 create mode 100644 dev-python/dask-expr/dask-expr-1.0.1.ebuild
 create mode 100644 dev-python/dask-expr/metadata.xml

(limited to 'dev-python/dask-expr')

diff --git a/dev-python/dask-expr/Manifest b/dev-python/dask-expr/Manifest
new file mode 100644
index 000000000000..8ed08e0ea3dc
--- /dev/null
+++ b/dev-python/dask-expr/Manifest
@@ -0,0 +1,3 @@
+DIST dask-expr-1.0.1.gh.tar.gz 233067 BLAKE2B 8638c7f457aa7decdad71de95f4a1ebc2af32781a28ef6e76fc4f59cd2c417ce3f005e77b42553625e045c44c9574686a549c48a44acb7939da467bb5ef603d1 SHA512 6de85ee49c55f36e20b75c4df48b757e278e6e4dba85ee30ecf33644c5533e0424c55de03b4d37beef33d00bd52000f7d2ddbc3d762d31e8999e2657eea1778d
+EBUILD dask-expr-1.0.1.ebuild 1143 BLAKE2B 9c5574c6162db8f6bad2c418a3dde0fe0d52ab85465481cf9451532b897e1b0dee3f1b0d6b3db53b8140b7f8bf86037848121b73aaf50fda5fe079f48e79aff7 SHA512 7473f846eed2a568cb4651822400d9af4a956bfb546640214a1a4a8d69cef7d283c6b9a9babf1939fe55b98e4a47a0168e755317c7225404d9b8c423387d425c
+MISC metadata.xml 369 BLAKE2B 38dfcaeb0144094d8da213fdf05186a59db6d252f0328ffb3b4030e2a4db300e4af0f1f06a868eb80c68f831fc25aaab450f951890db737924662560087dc5fb SHA512 b6ab843478467faa7561eff3282e19fcf0e4e5280c22b5cf1ae4179b75c6e58ad8e98950ae6323099e4ec867220a59bc053962ca3fcb7c38004c9fd244cc1712
diff --git a/dev-python/dask-expr/dask-expr-1.0.1.ebuild b/dev-python/dask-expr/dask-expr-1.0.1.ebuild
new file mode 100644
index 000000000000..1d693e10092e
--- /dev/null
+++ b/dev-python/dask-expr/dask-expr-1.0.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="High Level Expressions for Dask"
+HOMEPAGE="
+	https://github.com/dask/dask-expr/
+	https://pypi.org/project/dask-expr/
+"
+# pypi tarball removes tests, as of 1.0.1
+SRC_URI="
+	https://github.com/dask/dask-expr/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/dask-2024.3.0[${PYTHON_USEDEP}]
+	>=dev-python/pyarrow-7.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pandas-2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/versioneer[${PYTHON_USEDEP}]
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin
+	sed -i -e '/dask/s:==:>=:' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# requires distributed
+		'dask_expr/tests/test_shuffle.py::test_respect_context_shuffle[shuffle]'
+	)
+	local EPYTEST_IGNORE=(
+		# requires distributed
+		dask_expr/io/tests/test_parquet.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
diff --git a/dev-python/dask-expr/metadata.xml b/dev-python/dask-expr/metadata.xml
new file mode 100644
index 000000000000..b20b7197b52f
--- /dev/null
+++ b/dev-python/dask-expr/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="github">dask/dask-expr</remote-id>
+		<remote-id type="pypi">dask-expr</remote-id>
+	</upstream>
+</pkgmetadata>
-- 
cgit v1.2.3