From aa3411e241a201d53a2689766fe419f2756819f3 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 24 Mar 2019 17:22:19 +0000
Subject: gentoo resync : 24.03.2019

---
 dev-python/clang-python/clang-python-8.0.0.ebuild | 47 +++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 dev-python/clang-python/clang-python-8.0.0.ebuild

(limited to 'dev-python/clang-python/clang-python-8.0.0.ebuild')

diff --git a/dev-python/clang-python/clang-python-8.0.0.ebuild b/dev-python/clang-python/clang-python-8.0.0.ebuild
new file mode 100644
index 000000000000..9a7fbe1d66a9
--- /dev/null
+++ b/dev-python/clang-python/clang-python-8.0.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6,3_7} )
+inherit python-r1
+
+MY_P=cfe-${PV/_/}.src
+DESCRIPTION="Python bindings for sys-devel/clang"
+HOMEPAGE="https://llvm.org/"
+SRC_URI="https://releases.llvm.org/${PV/_//}/${MY_P}.tar.xz"
+
+LICENSE="UoI-NCSA"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-fbsd"
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# The module is opening libclang.so directly, and doing some blasphemy
+# on top of it.
+RDEPEND="
+	>=sys-devel/clang-${PV}:*
+	!sys-devel/llvm:0[clang(-),python(-)]
+	!sys-devel/clang:0[python(-)]
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${MY_P}/bindings/python
+
+src_unpack() {
+	einfo "Unpacking parts of ${MY_P}.tar.xz ..."
+	tar -xJf "${DISTDIR}/${MY_P}.tar.xz" "${MY_P}/bindings/python" || die
+}
+
+python_test() {
+	"${EPYTHON}" -m unittest discover -v || die "Tests fail with ${EPYTHON}"
+}
+
+src_test() {
+	python_foreach_impl python_test
+}
+
+src_install() {
+	python_foreach_impl python_domodule clang
+}
-- 
cgit v1.2.3