From d162ba1860a88062f4cd61f8b52fc303ba0b2991 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 7 Aug 2021 00:16:33 +0100
Subject: gentoo resync : 07.08.2021

---
 .../cfn-python-lint/cfn-python-lint-0.53.0.ebuild  | 57 ++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 dev-python/cfn-python-lint/cfn-python-lint-0.53.0.ebuild

(limited to 'dev-python/cfn-python-lint/cfn-python-lint-0.53.0.ebuild')

diff --git a/dev-python/cfn-python-lint/cfn-python-lint-0.53.0.ebuild b/dev-python/cfn-python-lint/cfn-python-lint-0.53.0.ebuild
new file mode 100644
index 000000000000..5c43ac1c42b8
--- /dev/null
+++ b/dev-python/cfn-python-lint/cfn-python-lint-0.53.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..9} )
+inherit distutils-r1
+
+# TODO: pkgmove to cfn-lint
+MY_P=${P/-python}
+DESCRIPTION="CloudFormation Linter"
+HOMEPAGE="https://pypi.org/project/cfn-lint/ https://github.com/aws-cloudformation/cfn-lint/"
+SRC_URI="
+	https://github.com/aws-cloudformation/cfn-lint/archive/v${PV}.tar.gz
+		-> ${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/aws-sam-translator-1.38.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/importlib_resources[${PYTHON_USEDEP}]
+	' python3_6)
+	dev-python/jsonpatch[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.0[${PYTHON_USEDEP}]
+	dev-python/junit-xml[${PYTHON_USEDEP}]
+	dev-python/networkx[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.4[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.15.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.11[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests --install unittest
+
+PATCHES=(
+	"${FILESDIR}/cfn-python-lint-0.30.1-tests.patch"
+)
+
+src_prepare() {
+	# unpin the deps
+	sed -e 's:~=[0-9.]*::' -i setup.py || die
+	# requires git checkout
+	sed -e 's:test_update_docs:_&:' \
+		-i test/unit/module/maintenance/test_update_documentation.py || die
+	# requires Internet
+	sed -e 's:test_update_resource_specs_python:_&:' \
+		-i test/unit/module/maintenance/test_update_resource_specs.py || die
+	distutils-r1_src_prepare
+}
-- 
cgit v1.2.3