From 3b08f674e3f771b49370edb144dab0958c8cf721 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Tue, 31 Aug 2021 08:59:54 +0100
Subject: gentoo resync : 31.08.2021

---
 dev-python/cfn-lint/cfn-lint-0.53.1.ebuild | 54 ++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 dev-python/cfn-lint/cfn-lint-0.53.1.ebuild

(limited to 'dev-python/cfn-lint/cfn-lint-0.53.1.ebuild')

diff --git a/dev-python/cfn-lint/cfn-lint-0.53.1.ebuild b/dev-python/cfn-lint/cfn-lint-0.53.1.ebuild
new file mode 100644
index 000000000000..f483fd0763d2
--- /dev/null
+++ b/dev-python/cfn-lint/cfn-lint-0.53.1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..9} )
+inherit distutils-r1
+
+DESCRIPTION="CloudFormation Linter"
+HOMEPAGE="https://pypi.org/project/cfn-lint/ https://github.com/aws-cloudformation/cfn-lint/"
+SRC_URI="
+	https://github.com/aws-cloudformation/cfn-lint/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/aws-sam-translator-1.38.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/importlib_resources[${PYTHON_USEDEP}]
+	' python3_6)
+	dev-python/jsonpatch[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.0[${PYTHON_USEDEP}]
+	dev-python/junit-xml[${PYTHON_USEDEP}]
+	dev-python/networkx[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.4[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.15.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.11[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests --install unittest
+
+PATCHES=(
+	"${FILESDIR}/cfn-lint-0.30.1-tests.patch"
+)
+
+src_prepare() {
+	# unpin the deps
+	sed -e 's:~=[0-9.]*::' -i setup.py || die
+	# requires git checkout
+	sed -e 's:test_update_docs:_&:' \
+		-i test/unit/module/maintenance/test_update_documentation.py || die
+	# requires Internet
+	sed -e 's:test_update_resource_specs_python:_&:' \
+		-i test/unit/module/maintenance/test_update_resource_specs.py || die
+	distutils-r1_src_prepare
+}
-- 
cgit v1.2.3