From 0f558761aa2dee1017b4751e4017205e015a9560 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 29 Jun 2022 12:04:12 +0100
Subject: gentoo resync : 29.12.2022

---
 dev-python/bracex/bracex-2.3_p1.ebuild | 56 ++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 dev-python/bracex/bracex-2.3_p1.ebuild

(limited to 'dev-python/bracex/bracex-2.3_p1.ebuild')

diff --git a/dev-python/bracex/bracex-2.3_p1.ebuild b/dev-python/bracex/bracex-2.3_p1.ebuild
new file mode 100644
index 000000000000..8ac52e0eef59
--- /dev/null
+++ b/dev-python/bracex/bracex-2.3_p1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+DISTUTILS_USE_PEP517=hatchling
+
+DOCS_BUILDER="mkdocs"
+DOCS_DEPEND="
+	dev-python/mkdocs-git-revision-date-localized-plugin
+	dev-python/mkdocs-material
+	dev-python/mkdocs-minify-plugin
+	dev-python/mkdocs_pymdownx_material_extras
+	dev-python/pyspelling
+"
+
+inherit distutils-r1 docs
+
+MY_PV="${PV%_p1}.post1"
+
+DESCRIPTION="Bash style brace expansion for Python"
+HOMEPAGE="
+	https://github.com/facelessuser/bracex/
+	https://pypi.org/project/bracex/
+"
+SRC_URI="
+	https://github.com/facelessuser/${PN}/archive/${MY_PV}.tar.gz
+		-> ${P}.tar.gz
+"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 ~riscv x86"
+
+BDEPEND="
+	test? (
+		dev-vcs/git
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# mkdocs-git-revision-date-localized-plugin needs git repo
+	if use doc; then
+		git init || die
+		git config --global user.email "you@example.com" || die
+		git config --global user.name "Your Name" || die
+		git add . || die
+		git commit -m 'init' || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
-- 
cgit v1.2.3