From ab7810b87f5bb33b3ed5edd0dbda7f4bcd0cf70d Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 13 Sep 2023 22:45:20 +0100
Subject: gentoo auto-resync : 13:09:2023 - 22:45:20

---
 dev-python/botocore/botocore-1.31.46.ebuild | 68 +++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)
 create mode 100644 dev-python/botocore/botocore-1.31.46.ebuild

(limited to 'dev-python/botocore/botocore-1.31.46.ebuild')

diff --git a/dev-python/botocore/botocore-1.31.46.ebuild b/dev-python/botocore/botocore-1.31.46.ebuild
new file mode 100644
index 000000000000..7cacb5c3f634
--- /dev/null
+++ b/dev-python/botocore/botocore-1.31.46.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/boto/botocore/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	local -x EPYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit} -p xdist -n "$(makeopts_jobs)"
+}
-- 
cgit v1.2.3