From 66a7d60eb8beba754ba79c2752cbf70fcf741b0b Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 5 Mar 2024 07:05:51 +0000
Subject: gentoo auto-resync : 05:03:2024 - 07:05:50

---
 dev-python/boto3/boto3-1.34.55.ebuild | 58 +++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 dev-python/boto3/boto3-1.34.55.ebuild

(limited to 'dev-python/boto3/boto3-1.34.55.ebuild')

diff --git a/dev-python/boto3/boto3-1.34.55.ebuild b/dev-python/boto3/boto3-1.34.55.ebuild
new file mode 100644
index 000000000000..b64e7191fd19
--- /dev/null
+++ b/dev-python/boto3/boto3-1.34.55.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+SRC_URI="
+	https://github.com/boto/boto3/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/botocore-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.10.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
-- 
cgit v1.2.3