From d162ba1860a88062f4cd61f8b52fc303ba0b2991 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 7 Aug 2021 00:16:33 +0100
Subject: gentoo resync : 07.08.2021

---
 dev-python/bleach/bleach-4.0.0.ebuild | 41 +++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)
 create mode 100644 dev-python/bleach/bleach-4.0.0.ebuild

(limited to 'dev-python/bleach/bleach-4.0.0.ebuild')

diff --git a/dev-python/bleach/bleach-4.0.0.ebuild b/dev-python/bleach/bleach-4.0.0.ebuild
new file mode 100644
index 000000000000..a2c284761436
--- /dev/null
+++ b/dev-python/bleach/bleach-4.0.0.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="An easy whitelist-based HTML-sanitizing tool"
+HOMEPAGE="
+	https://github.com/mozilla/bleach/
+	https://pypi.org/project/bleach/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/html5lib-1.0.1-r1[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/bleach-3.2.1-py39.patch
+)
+
+src_prepare() {
+	# unbundle unpatched broken html5lib
+	rm -r bleach/_vendor || die
+	sed -i -e 's:bleach\._vendor\.::' \
+		bleach/html5lib_shim.py \
+		bleach/sanitizer.py \
+		tests/test_clean.py || die
+	# indirect html5lib deps
+	sed -i -e '/six/d' -e '/webencodings/d' setup.py || die
+
+	distutils-r1_src_prepare
+}
-- 
cgit v1.2.3