From 40aaaa64e86ba6710bbeb31c4615a6ce80e75e11 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 28 Apr 2021 20:21:43 +0100
Subject: gentoo resync : 28.04.2021

---
 dev-python/astroid/astroid-2.5.5.ebuild | 47 +++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 dev-python/astroid/astroid-2.5.5.ebuild

(limited to 'dev-python/astroid/astroid-2.5.5.ebuild')

diff --git a/dev-python/astroid/astroid-2.5.5.ebuild b/dev-python/astroid/astroid-2.5.5.ebuild
new file mode 100644
index 000000000000..a1a4c659cf62
--- /dev/null
+++ b/dev-python/astroid/astroid-2.5.5.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Abstract Syntax Tree for logilab packages"
+HOMEPAGE="
+	https://github.com/PyCQA/astroid/
+	https://pypi.org/project/astroid/"
+SRC_URI="
+	https://github.com/PyCQA/astroid/archive/${P}.tar.gz"
+S=${WORKDIR}/${PN}-${P}
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+# Version specified in __pkginfo__.py.
+RDEPEND="
+	>=dev-python/lazy-object-proxy-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/wrapt-1.11.2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/typed-ast-1.4.0[${PYTHON_USEDEP}]
+	' python3_7)"
+BDEPEND="
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local deselect=(
+		# no clue why it's broken
+		tests/unittest_modutils.py::GetModulePartTest::test_knownValues_get_builtin_module_part
+	)
+
+	# Faker causes sys.path_importer_cache keys to be overwritten
+	# with PosixPaths
+	epytest -p no:faker ${deselect[@]/#/--deselect }
+}
-- 
cgit v1.2.3