From e2db47eaae00ec33f8971db44b68645c5d3b9590 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Tue, 17 Aug 2021 11:36:49 +0100
Subject: gentoo resync : 17.08.2021

---
 dev-python/aioredis/aioredis-2.0.0.ebuild | 56 +++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 dev-python/aioredis/aioredis-2.0.0.ebuild

(limited to 'dev-python/aioredis/aioredis-2.0.0.ebuild')

diff --git a/dev-python/aioredis/aioredis-2.0.0.ebuild b/dev-python/aioredis/aioredis-2.0.0.ebuild
new file mode 100644
index 000000000000..d2e9e1e4bcf8
--- /dev/null
+++ b/dev-python/aioredis/aioredis-2.0.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+inherit distutils-r1 optfeature
+
+DESCRIPTION="asyncio Redis client library"
+HOMEPAGE="https://pypi.org/project/aioredis/ https://github.com/aio-libs/aioredis-py"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/async_timeout[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-db/redis
+		dev-python/hiredis[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	local redis_pid="${T}"/redis.pid
+	local redis_port=6379
+	local redis_test_config="
+		daemonize yes
+		pidfile ${redis_pid}
+		port ${redis_port}
+		bind 127.0.0.1
+	"
+
+	elog "Spawning Redis"
+	elog "NOTE: Port ${redis_port} must be free"
+	"${EPREFIX}"/usr/sbin/redis-server - <<< "${redis_test_config}" || die
+
+	# Run the tests
+	distutils-r1_src_test
+
+	# Clean up afterwards
+	kill "$(<"${redis_pid}")" || die
+}
+
+pkg_postinst() {
+	optfeature "hiredis parser" dev-python/hiredis
+}
-- 
cgit v1.2.3