From 068424b26532f3551a81421a9be67ed206e5c11a Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 11 Aug 2021 07:02:28 +0100
Subject: gentoo resync : 11.08.2021

---
 dev-python/PySDL2/PySDL2-0.9.8.ebuild | 55 +++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 dev-python/PySDL2/PySDL2-0.9.8.ebuild

(limited to 'dev-python/PySDL2/PySDL2-0.9.8.ebuild')

diff --git a/dev-python/PySDL2/PySDL2-0.9.8.ebuild b/dev-python/PySDL2/PySDL2-0.9.8.ebuild
new file mode 100644
index 000000000000..e3b42a45db2c
--- /dev/null
+++ b/dev-python/PySDL2/PySDL2-0.9.8.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+DESCRIPTION="Python (ctypes) bindings for SDL2 libraries"
+HOMEPAGE="https://github.com/marcusva/py-sdl2 https://pypi.org/project/PySDL2/"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="|| ( public-domain CC0-1.0 ZLIB )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+# Optional deps:
+# - dev-python/numpy,
+# - dev-python/pillow,
+# - media-libs/sdl2-* (loaded dynamically via ctypes).
+#
+# If a reverse dependency needs the specific module, it should
+# explicitly depend on the optional module in question. You also
+# probably need to explicitly require some media-libs/libsdl2 flags.
+RDEPEND="media-libs/libsdl2"
+
+# Require all of SDL2 libraries and at least the most common subsystems
+# for better test coverage.
+DEPEND="
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		media-libs/libsdl2[joystick,sound,video]
+		media-libs/sdl2-gfx
+		media-libs/sdl2-image[gif,jpeg,png,tiff,webp]
+		|| (
+			media-libs/sdl2-mixer[flac]
+			media-libs/sdl2-mixer[midi]
+			media-libs/sdl2-mixer[mod]
+			media-libs/sdl2-mixer[mp3]
+			media-libs/sdl2-mixer[opus]
+		)
+		media-libs/sdl2-ttf
+	)"
+
+distutils_enable_tests pytest
+
+src_test() {
+	# from .travis.yml
+	local -x SDL_VIDEODRIVER=dummy
+	local -x SDL_AUDIODRIVER=dummy
+	local -x SDL_RENDER_DRIVER=software
+
+	distutils-r1_src_test
+}
-- 
cgit v1.2.3