From 5a165c60b9b8c4847067cb83b4be7da785d01f93 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 28 Sep 2019 08:17:07 +0100
Subject: gentoo resync : 28.09.2019

---
 .../PyQtWebEngine-5.13.2_pre1909181828.ebuild      | 73 ++++++++++++++++++++++
 1 file changed, 73 insertions(+)
 create mode 100644 dev-python/PyQtWebEngine/PyQtWebEngine-5.13.2_pre1909181828.ebuild

(limited to 'dev-python/PyQtWebEngine/PyQtWebEngine-5.13.2_pre1909181828.ebuild')

diff --git a/dev-python/PyQtWebEngine/PyQtWebEngine-5.13.2_pre1909181828.ebuild b/dev-python/PyQtWebEngine/PyQtWebEngine-5.13.2_pre1909181828.ebuild
new file mode 100644
index 000000000000..2492f56e0e0e
--- /dev/null
+++ b/dev-python/PyQtWebEngine/PyQtWebEngine-5.13.2_pre1909181828.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+inherit python-r1 qmake-utils
+
+DESCRIPTION="Python bindings for QtWebEngine"
+HOMEPAGE="https://www.riverbankcomputing.com/software/pyqtwebengine/intro"
+
+MY_PN=PyQtWebEngine
+MY_P=${MY_PN}_gpl-${PV/_pre/.dev}
+if [[ ${PV} == *_pre* ]]; then
+	SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.gz"
+else
+	SRC_URI="https://www.riverbankcomputing.com/static/Downloads/${MY_PN}/${PV}/${MY_P}.tar.gz"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="debug"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-python/PyQt5-5.13.1[gui,network,printsupport,ssl,webchannel,widgets,${PYTHON_USEDEP}]
+	>=dev-python/PyQt5-sip-4.19.14:=[${PYTHON_USEDEP}]
+	dev-qt/qtcore:5
+	dev-qt/qtwebengine:5[widgets]
+"
+DEPEND="${RDEPEND}
+	>=dev-python/sip-4.19.14[${PYTHON_USEDEP}]
+"
+
+S=${WORKDIR}/${MY_P}
+
+src_configure() {
+	configuration() {
+		local myconf=(
+			"${PYTHON}"
+			"${S}"/configure.py
+			--qmake="$(qt5_get_bindir)"/qmake
+			$(usex debug '--debug --trace' '')
+			--verbose
+		)
+		echo "${myconf[@]}"
+		"${myconf[@]}" || die
+
+		# Fix parallel install failure
+		sed -i -e '/INSTALLS += distinfo/i distinfo.depends = install_subtargets' ${MY_PN}.pro || die
+
+		# Run eqmake to respect toolchain and build flags
+		eqmake5 -recursive ${MY_PN}.pro
+	}
+	python_foreach_impl run_in_build_dir configuration
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	installation() {
+		emake INSTALL_ROOT="${D}" install
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir installation
+
+	einstalldocs
+}
-- 
cgit v1.2.3