From 0f558761aa2dee1017b4751e4017205e015a9560 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 29 Jun 2022 12:04:12 +0100
Subject: gentoo resync : 29.12.2022

---
 .../MechanicalSoup/MechanicalSoup-1.1.0-r1.ebuild  | 48 ++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 dev-python/MechanicalSoup/MechanicalSoup-1.1.0-r1.ebuild

(limited to 'dev-python/MechanicalSoup/MechanicalSoup-1.1.0-r1.ebuild')

diff --git a/dev-python/MechanicalSoup/MechanicalSoup-1.1.0-r1.ebuild b/dev-python/MechanicalSoup/MechanicalSoup-1.1.0-r1.ebuild
new file mode 100644
index 000000000000..4c41e80353e7
--- /dev/null
+++ b/dev-python/MechanicalSoup/MechanicalSoup-1.1.0-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="A python library for automating interaction with websites"
+HOMEPAGE="https://pypi.org/project/MechanicalSoup/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/beautifulsoup4-4.7[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.22.0[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/requests-mock-1.3.0[${PYTHON_USEDEP}]
+		dev-python/pytest-httpbin[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs
+
+python_prepare_all() {
+	# Override pytest options to skip coverage and flake8
+	sed -e '/^addopts =/d' -i setup.cfg || die
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3