From 6c30cc2d5bd48ddbdbe8d75544899cd5dbfcaba4 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 14 Jul 2018 20:18:26 +0100
Subject: gentoo resync : 14.07.2018

---
 dev-python/Babel/Babel-2.6.0.ebuild | 49 +++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 dev-python/Babel/Babel-2.6.0.ebuild

(limited to 'dev-python/Babel/Babel-2.6.0.ebuild')

diff --git a/dev-python/Babel/Babel-2.6.0.ebuild b/dev-python/Babel/Babel-2.6.0.ebuild
new file mode 100644
index 000000000000..aaf13989c173
--- /dev/null
+++ b/dev-python/Babel/Babel-2.6.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{4,5,6}} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Collection of tools for internationalizing Python applications"
+HOMEPAGE="http://babel.pocoo.org/ https://pypi.org/project/Babel/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris"
+IUSE="doc test"
+
+RDEPEND="dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+DEPEND="${DEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	# Make the tests use implementation-specific datadir,
+	# because they try to write in it.
+	sed -e '/datadir =/s:os\.path\.dirname(__file__):os.environ["BUILD_DIR"]:' \
+		-i tests/messages/test_frontend.py || die
+	sed -e '/^intersphinx_mapping/,+3d' -i docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x TZ=UTC
+
+	# Create implementation-specific datadir for tests.
+	cp -R -l tests/messages/data "${BUILD_DIR}"/ || die
+	py.test -vv || die
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
-- 
cgit v1.2.3