From 8376ef56580626e9c0f796d5b85b53a0a1c7d5f5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 14 Jul 2018 21:03:06 +0100
Subject: gentoo resync : 14.07.2018

---
 dev-php/PEAR-Crypt_GPG/PEAR-Crypt_GPG-1.6.3.ebuild | 46 ++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 dev-php/PEAR-Crypt_GPG/PEAR-Crypt_GPG-1.6.3.ebuild

(limited to 'dev-php/PEAR-Crypt_GPG/PEAR-Crypt_GPG-1.6.3.ebuild')

diff --git a/dev-php/PEAR-Crypt_GPG/PEAR-Crypt_GPG-1.6.3.ebuild b/dev-php/PEAR-Crypt_GPG/PEAR-Crypt_GPG-1.6.3.ebuild
new file mode 100644
index 000000000000..f40428e9b276
--- /dev/null
+++ b/dev-php/PEAR-Crypt_GPG/PEAR-Crypt_GPG-1.6.3.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN="${PN/PEAR-/}"
+MY_PV="${PV/_/}"
+MY_P="${MY_PN}-${MY_PV}"
+
+DESCRIPTION="PHP interface to the GNU Privacy Guard (GnuPG)"
+HOMEPAGE="http://pear.php.net/package/${MY_PN}"
+SRC_URI="http://download.pear.php.net/package/${MY_P}.tgz"
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="test"
+
+RDEPEND="app-crypt/gnupg
+	dev-lang/php:*[posix,unicode]
+	dev-php/PEAR-Console_CommandLine
+	dev-php/PEAR-Exception"
+BDEPEND="test? ( ${RDEPEND} dev-php/phpunit )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+	sed -i "s|@bin-dir@|${EPREFIX}/usr/bin|" Crypt/GPG/Engine.php || die
+	sed -i "s|@package-name@|${MY_PN}|" Crypt/GPG/PinEntry.php || die
+	sed -i "s|@data-dir@|${EPREFIX}/usr/share|" Crypt/GPG/PinEntry.php || die
+}
+
+src_install() {
+	dodoc README.md
+	dobin scripts/crypt-gpg-pinentry
+
+	insinto "/usr/share/${MY_PN}"
+	doins -r data
+
+	insinto /usr/share/php
+	doins -r Crypt
+}
+
+src_test() {
+	phpunit tests/ || die "test suite failed"
+}
-- 
cgit v1.2.3