From 2719f73b6813d11d13a9650cdd2ab8ec6e69385d Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 9 Jul 2022 15:43:36 +0100
Subject: gentoo resync : 09.07.2022

---
 dev-ml/utop/utop-2.9.0-r1.ebuild | 63 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)
 create mode 100644 dev-ml/utop/utop-2.9.0-r1.ebuild

(limited to 'dev-ml/utop/utop-2.9.0-r1.ebuild')

diff --git a/dev-ml/utop/utop-2.9.0-r1.ebuild b/dev-ml/utop/utop-2.9.0-r1.ebuild
new file mode 100644
index 000000000000..cd05e5fc7a0c
--- /dev/null
+++ b/dev-ml/utop/utop-2.9.0-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit dune elisp-common
+
+DESCRIPTION="Universal toplevel for OCaml"
+HOMEPAGE="https://github.com/ocaml-community/utop"
+SRC_URI="https://github.com/ocaml-community/utop/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~x86"
+IUSE="emacs +ocamlopt"
+
+ELISP_DEPEND="
+	emacs? (
+		>=app-editors/emacs-24:*
+		>=app-emacs/tuareg-mode-2.2.0
+	)
+"
+DEPEND="
+	dev-ml/camomile:=
+	dev-ml/lambda-term:=
+	dev-ml/lwt:=
+	dev-ml/react:=
+"
+RDEPEND="
+	${DEPEND}
+	${ELISP_DEPEND}
+"
+BDEPEND="
+	dev-ml/cppo
+	dev-ml/findlib
+	${ELISP_DEPEND}
+"
+
+SITEFILE="50${PN}-gentoo.el"
+
+src_compile() {
+	dune_src_compile
+
+	use emacs &&
+		BYTECOMPFLAGS="-L src/top" elisp-compile src/top/*.el
+}
+
+src_install() {
+	dune_src_install
+
+	if use emacs ; then
+		elisp-install ${PN} src/top/*.el{,c}
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}
-- 
cgit v1.2.3