From d36c5f9e59f92a021c987989cd79d44460e0da42 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 31 Jan 2023 21:02:55 +0000
Subject: gentoo auto-resync : 31:01:2023 - 21:02:55

---
 dev-ml/extlib/extlib-1.7.7-r1.ebuild | 60 ++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 dev-ml/extlib/extlib-1.7.7-r1.ebuild

(limited to 'dev-ml/extlib/extlib-1.7.7-r1.ebuild')

diff --git a/dev-ml/extlib/extlib-1.7.7-r1.ebuild b/dev-ml/extlib/extlib-1.7.7-r1.ebuild
new file mode 100644
index 000000000000..b21b2aaa3217
--- /dev/null
+++ b/dev-ml/extlib/extlib-1.7.7-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit findlib vcs-clean
+
+DESCRIPTION="Standard library extensions for O'Caml"
+HOMEPAGE="https://github.com/ygrek/ocaml-extlib"
+SRC_URI="https://github.com/ygrek/ocaml-extlib/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="doc +ocamlopt"
+
+# See bug #704146
+BDEPEND=">=dev-ml/cppo-1.6.6"
+RDEPEND="dev-lang/ocaml:=[ocamlopt?]"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.7.7-no-git.patch
+	"${FILESDIR}"/0001-Add-support-for-OCaml-4.12.patch
+	"${FILESDIR}"/0002-caml_hash_univ_param-was-removed-for-OCaml-pre-4.00-.patch
+)
+
+S="${WORKDIR}/ocaml-${P}"
+
+src_prepare() {
+	default
+	egit_clean
+}
+
+src_compile() {
+	cd src || die
+	emake -j1 all
+	if use ocamlopt; then
+		emake opt cmxs
+	fi
+
+	if use doc; then
+		emake doc
+	fi
+}
+
+src_test() {
+	emake -j1 test
+}
+
+src_install() {
+	findlib_src_install
+
+	# install documentation
+	dodoc README.md
+
+	if use doc; then
+		dodoc -r src/doc/
+	fi
+}
-- 
cgit v1.2.3