From 5d8ffbc273ca664e15618d557ced3e02de1a884b Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 7 Jul 2024 12:24:47 +0100
Subject: gentoo auto-resync : 07:07:2024 - 12:24:46

---
 dev-ml/cudf/Manifest            |  3 +-
 dev-ml/cudf/cudf-0.10-r1.ebuild | 99 +++++++++++++++++++++++++++++++++++++++++
 dev-ml/cudf/cudf-0.10.ebuild    |  6 +--
 3 files changed, 104 insertions(+), 4 deletions(-)
 create mode 100644 dev-ml/cudf/cudf-0.10-r1.ebuild

(limited to 'dev-ml/cudf')

diff --git a/dev-ml/cudf/Manifest b/dev-ml/cudf/Manifest
index 584558351d82..e0c2de72754d 100644
--- a/dev-ml/cudf/Manifest
+++ b/dev-ml/cudf/Manifest
@@ -1,6 +1,7 @@
 AUX ounit2.patch 380 BLAKE2B 20d0c2f0b719715fc5f111bfbd81e814a4ae8229a7365ed2073d0ecc3ad1eafa4377bc3c0e497d4bf0ab73af986255ac48e179d34dfb2ded3fd7b55c22f339ba SHA512 d53ac28ba8b8eeda612d7f323bb658f272dcc785596eb47b4148ed7954a6ca0204e42b5e3cb6a55211fc1117432f3088fdc215930c26238dc2d34f063f21b062
 DIST cudf-0.9.tar.gz 55124 BLAKE2B 013f97d13b732674a7d0f9188590bbb8150ae9dc32ce26b56fb04848629fb27a3c850aa327e687d6aa80eb62ba6f67af2fcf86a647520e73d7f76748871a79cc SHA512 4abdd1a5a3d616273abe9dda87450a922ecd69b64d32f34d8fa3086bbd07fd23ffb01c24b128bf4d1c0c817cfa1da8029e743d33b3ad6a04e7a8f706b098c427
 DIST cudf-v0.10.tar.bz2 47664 BLAKE2B 6ecdfc4243d80f12f6904b334f93ff47beb94535b6ba84992c6a31d244a7c2dcb6072e67828d96b31d4628bb244022fd962efcdcae5299f5a57694f3aa6c95a8 SHA512 b36ecad224070d2c07d4123fb7e39160390ddec4196505e66aad9fbd982bd7ca320ff5f0e771e7996da49bff22fb87fc057060277695b75cd68de19e57cb3855
-EBUILD cudf-0.10.ebuild 1710 BLAKE2B 64530e269c54152473d3467428301c3bbc93d2aa705ea547fa8b00a6cf5a78039c6cfd781d235671fae8a5f081721001c9897ca87a1e2bc13d768b06ea344de9 SHA512 e421b96af33c2006ea56e3d601cee5187c5442e45e7c5a8b010bcab5cf390d28ad8d483f3c71c321b32c6d1c27f92614ac2f0ebe950db54959da34b36e500948
+EBUILD cudf-0.10-r1.ebuild 2221 BLAKE2B 2d1ee3a8ac3899a13d4cd0f31f30e45cda679b3c69dcc7208650807d535e2ae31eb6577f2eafae5e7f5fd3575899dc677bb3954c04af3e039a26848fe9614ea1 SHA512 95830ab4f649d99e12a49df5ec0dfe8fd3ec1675c5b494b5d30c4541a20b3c2cddbafdf6dd42bbc786e49f8c9bcedfa23471ba473f3b97b355476b5be86c1da9
+EBUILD cudf-0.10.ebuild 1710 BLAKE2B ab657db9f01691d6a82c2e71a58893c2563b1e67a0fd5e67d28b616bbebcf7a4d5e46bde7cb55a36264b907c7ef36fded130d81f8a0da7342b1c612aafe2028e SHA512 c30f9cfcc454093955762071fa56528b3c41ceee220c7e92a4cd887fb2f60298a814892b1be7c6628f9ff7d27ebc14f9ec15b6b6be539306f212b395415fc933
 EBUILD cudf-0.9-r2.ebuild 1842 BLAKE2B d8461a2af2d7e06d2f58ec11d87de3b1a4e24cbd7bb902b7d9ece589230313d1bb06b7ab7c729011b66188b14024ebb961f12c9689719c36b7a2f4dc396ee77d SHA512 b28fcb640bbb14d80c1dd45eb1a3c5c71a7412ae0eb6243095d1388d7e01d27e2a11ed00806a6562d82d192fdf05477ff5fcdfa6c467780ddc5ec1da6ddefebb
 MISC metadata.xml 308 BLAKE2B 3ef59c1feb944f3cc9773629c5c4da487557829efb4764ce4b58f70c4a6c958bf675402ade39dde82b9f433c40d7933f4dcd372c529aec41a59a413287d43ee2 SHA512 4d7af5033b612da1fb1d2a80676c1e2a9818566c69c585c72554ac3fb827ea8bf216a59b9fb61ca0c2d74ea5745d6559d819e58512d100d482b9b53f5af3dd7d
diff --git a/dev-ml/cudf/cudf-0.10-r1.ebuild b/dev-ml/cudf/cudf-0.10-r1.ebuild
new file mode 100644
index 000000000000..c77436962e30
--- /dev/null
+++ b/dev-ml/cudf/cudf-0.10-r1.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit dune toolchain-funcs
+
+MYP=${PN}-v${PV}
+DESCRIPTION="Library to parse, pretty print, and evaluate CUDF documents"
+HOMEPAGE="http://www.mancoosi.org/cudf/"
+SRC_URI="https://gitlab.com/irill/${PN}/-/archive/v${PV}/${MYP}.tar.bz2"
+
+S="${WORKDIR}"/${MYP}
+
+LICENSE="LGPL-3+"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="+ocamlopt llvm-libunwind test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-ml/extlib:=
+	dev-ml/findlib:=
+	dev-libs/glib:2
+	llvm-libunwind? ( sys-libs/llvm-libunwind:= )
+	!llvm-libunwind? ( sys-libs/libunwind:= )
+	sys-libs/ncurses:=
+	app-arch/zstd
+"
+DEPEND="${RDEPEND}
+	test? ( dev-ml/ounit2 )
+	dev-ml/ocamlbuild
+	dev-lang/perl
+"
+BDEPEND="virtual/pkgconfig"
+
+QA_FLAGS_IGNORED='.*'
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e 's|make|$(MAKE)|g' \
+		Makefile || die
+
+	if has_version ">=dev-lang/ocaml-5" ; then
+		sed -i \
+			-e 's|-lncurses|$(shell ${PKG_CONFIG} --libs ncurses glib-2.0) -lunwind -lzstd|g' \
+			-e "s|ar r|$(tc-getAR) r|g" \
+			c-lib/Makefile || die
+		sed -i \
+			-e 's|-lcurses|$(shell ${PKG_CONFIG} --libs ncurses glib-2.0) -lunwind -lzstd|g' \
+			c-lib/Makefile.variants || die
+		if use ocamlopt ; then
+			sed -i \
+				-e 's|-lunix|-lunixnat|g' \
+				c-lib/Makefile || die
+		else
+			sed -i \
+				-e 's|-lunix|-lunixbyt|g' \
+				c-lib/Makefile || die
+		fi
+	else
+		sed -i \
+			-e 's|-lncurses|$(shell ${PKG_CONFIG} --libs ncurses glib-2.0) -lunwind|g' \
+			-e "s|ar r|$(tc-getAR) r|g" \
+			c-lib/Makefile || die
+		sed -i \
+			-e 's|-lcurses|$(shell ${PKG_CONFIG} --libs ncurses glib-2.0) -lunwind|g' \
+			c-lib/Makefile.variants || die
+	fi
+
+	tc-export CC PKG_CONFIG
+
+	sed -i \
+		-e "s|-lncurses|$( $(tc-getPKG_CONFIG) --libs ncurses)|g" \
+		c-lib/cudf.pc.in || die
+}
+
+src_compile() {
+	dune_src_compile
+	emake c-lib
+	if use ocamlopt ; then
+		emake c-lib-opt
+	fi
+}
+
+src_test() {
+	dune_src_test
+	emake c-lib-test
+}
+
+src_install() {
+	dune_src_install
+	mv "${ED}"/usr/share/doc/${PF}/{cudf/README,} || die
+	rmdir "${ED}"/usr/share/doc/${PF}/cudf || die
+	emake DESTDIR="${ED}" -C c-lib/ LIBDIR="/usr/$(get_libdir)" -e install
+	dodoc BUGS ChangeLog
+}
diff --git a/dev-ml/cudf/cudf-0.10.ebuild b/dev-ml/cudf/cudf-0.10.ebuild
index 00c999757bff..d4e45e0e014f 100644
--- a/dev-ml/cudf/cudf-0.10.ebuild
+++ b/dev-ml/cudf/cudf-0.10.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -10,6 +10,8 @@ DESCRIPTION="Library to parse, pretty print, and evaluate CUDF documents"
 HOMEPAGE="http://www.mancoosi.org/cudf/"
 SRC_URI="https://gitlab.com/irill/${PN}/-/archive/v${PV}/${MYP}.tar.bz2"
 
+S="${WORKDIR}"/${MYP}
+
 LICENSE="LGPL-3"
 SLOT="0/${PV}"
 KEYWORDS="amd64 arm arm64 ~ppc ppc64 ~riscv x86"
@@ -34,8 +36,6 @@ BDEPEND="virtual/pkgconfig"
 
 QA_FLAGS_IGNORED='.*'
 
-S="${WORKDIR}"/${MYP}
-
 src_prepare() {
 	default
 
-- 
cgit v1.2.3