From 1c382dc5dbc52576ac2300fee0498af8af44e7b4 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 14 Jun 2023 15:21:15 +0100
Subject: Revert "gentoo auto-resync : 14:06:2023 - 15:13:45"

This reverts commit b9e8f3cc44aed3b6da71c7510c6287bf7bbbc66b.
---
 dev-libs/xmlsec/xmlsec-1.3.1.ebuild | 93 -------------------------------------
 1 file changed, 93 deletions(-)
 delete mode 100644 dev-libs/xmlsec/xmlsec-1.3.1.ebuild

(limited to 'dev-libs/xmlsec/xmlsec-1.3.1.ebuild')

diff --git a/dev-libs/xmlsec/xmlsec-1.3.1.ebuild b/dev-libs/xmlsec/xmlsec-1.3.1.ebuild
deleted file mode 100644
index 008af3b95a28..000000000000
--- a/dev-libs/xmlsec/xmlsec-1.3.1.ebuild
+++ /dev/null
@@ -1,93 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit autotools
-
-DESCRIPTION="Command line tool for signing, verifying, encrypting and decrypting XML"
-HOMEPAGE="https://www.aleksey.com/xmlsec"
-SRC_URI="https://www.aleksey.com/xmlsec/download/${PN}1-${PV}.tar.gz"
-S="${WORKDIR}/${PN}1-${PV}"
-
-LICENSE="MIT"
-# Upstream consider major version bumps to be changes in either X or Y in X.Y.Z
-SLOT="0/$(ver_cut 1-2)"
-KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
-IUSE="doc gcrypt gnutls http nss +openssl static-libs test"
-RESTRICT="!test? ( test )"
-REQUIRED_USE="
-	|| ( gnutls nss openssl )
-"
-
-RDEPEND="
-	>=dev-libs/libxml2-2.7.4
-	>=dev-libs/libxslt-1.0.20
-	dev-libs/libltdl
-	gcrypt? ( >=dev-libs/libgcrypt-1.4.0:= )
-	gnutls? ( >=net-libs/gnutls-3.6.13:= )
-	nss? (
-		>=dev-libs/nspr-4.4.1
-		>=dev-libs/nss-3.9
-	)
-	openssl? ( dev-libs/openssl:= )
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	virtual/pkgconfig
-	test? (
-		nss? (
-			>=dev-libs/nss-3.9[utils]
-		)
-	)
-"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-1.3.0-optimisation.patch
-)
-
-src_prepare() {
-	default
-
-	eautoreconf
-}
-
-src_configure() {
-	local myeconfargs=(
-		$(use_enable doc docs)
-		$(use_enable static-libs static)
-		$(use_with gcrypt)
-		$(use_with gnutls)
-		$(use_with nss nspr)
-		$(use_with nss)
-		$(use_with openssl)
-
-		--disable-werror
-		--enable-mans
-		--enable-pkgconfig
-
-		--enable-concatkdf
-		--enable-pbkdf2
-		--enable-ec
-		--enable-dh
-		--enable-sha3
-
-		--enable-files
-		$(use_enable http)
-		--disable-ftp
-	)
-
-	# Bash because of bug #721128
-	CONFIG_SHELL="${BROOT}"/bin/bash econf "${myeconfargs[@]}"
-}
-
-src_test() {
-	# See https://github.com/lsh123/xmlsec/issues/280 for TZ=UTC
-	TZ=UTC SHELL="${BROOT}"/bin/bash emake TMPFOLDER="${T}" check
-}
-
-src_install() {
-	default
-
-	find "${ED}" -name '*.la' -delete || die
-}
-- 
cgit v1.2.3