From 4cbcc855382a06088e2f016f62cafdbcb7e40665 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 20 Mar 2022 00:40:44 +0000
Subject: gentoo resync : 20.03.2022

---
 dev-libs/volume_key/volume_key-0.3.12-r4.ebuild | 61 +++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 dev-libs/volume_key/volume_key-0.3.12-r4.ebuild

(limited to 'dev-libs/volume_key/volume_key-0.3.12-r4.ebuild')

diff --git a/dev-libs/volume_key/volume_key-0.3.12-r4.ebuild b/dev-libs/volume_key/volume_key-0.3.12-r4.ebuild
new file mode 100644
index 000000000000..cc8940edb1c6
--- /dev/null
+++ b/dev-libs/volume_key/volume_key-0.3.12-r4.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..9} )
+
+inherit autotools python-single-r1
+
+DESCRIPTION="Library for manipulating and storing storage volume encryption keys"
+HOMEPAGE="https://pagure.io/volume_key"
+SRC_URI="http://releases.pagure.org/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~ia64 ~mips ppc ppc64 ~riscv sparc x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	app-crypt/gpgme:=
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	sys-apps/util-linux
+	sys-fs/cryptsetup:=
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/gettext
+	test? ( dev-libs/nss[utils] )
+"
+
+PATCHES=(
+	"${FILESDIR}/${P}-support_higher_LUKS_versions.patch"
+	"${FILESDIR}/${PN}-0.3.12-find_python3.patch" #764230
+)
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	eautoreconf #764230
+}
+
+src_configure() {
+	# --without-python disables python2
+	econf --without-python --with-python3
+}
+
+src_install() {
+	default
+	find "${ED}" -type f -name "*.la" -delete || die
+
+	python_optimize
+}
-- 
cgit v1.2.3