From 2719f73b6813d11d13a9650cdd2ab8ec6e69385d Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 9 Jul 2022 15:43:36 +0100
Subject: gentoo resync : 09.07.2022

---
 dev-libs/simdjson/simdjson-2.1.0-r1.ebuild | 85 ++++++++++++++++++++++++++++++
 1 file changed, 85 insertions(+)
 create mode 100644 dev-libs/simdjson/simdjson-2.1.0-r1.ebuild

(limited to 'dev-libs/simdjson/simdjson-2.1.0-r1.ebuild')

diff --git a/dev-libs/simdjson/simdjson-2.1.0-r1.ebuild b/dev-libs/simdjson/simdjson-2.1.0-r1.ebuild
new file mode 100644
index 000000000000..fd5c432b2c77
--- /dev/null
+++ b/dev-libs/simdjson/simdjson-2.1.0-r1.ebuild
@@ -0,0 +1,85 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs cmake
+
+DATA_HASH="a5b13babe65c1bba7186b41b43d4cbdc20a5c470"
+DESCRIPTION="SIMD accelerated C++ JSON library"
+HOMEPAGE="
+	https://simdjson.org/
+	https://github.com/simdjson/simdjson
+"
+SRC_URI="
+	https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz
+	test? ( https://github.com/${PN}/${PN}-data/archive/${DATA_HASH}.tar.gz -> ${PN}-data-${PV}.gh.tar.gz )
+"
+
+LICENSE="Apache-2.0 Boost-1.0 BSD MIT"
+SLOT="0/11"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="test tools"
+
+BDEPEND="
+	sys-apps/file
+	sys-apps/grep
+"
+DEPEND="
+	tools? ( dev-libs/cxxopts:= )
+"
+
+REQUIRED_USE="test? ( tools )"
+RESTRICT="!test? ( test )"
+
+PATCHES=(
+	"${FILESDIR}/simdjson-1.0.0-dont-bundle-cxxopts.patch"
+	"${FILESDIR}/simdjson-0.9.0-tests.patch"
+	"${FILESDIR}/simdjson-1.0.0-dont-fetch-data-tarball.patch"
+	"${FILESDIR}/simdjson-1.0.0-install-tools.patch"
+	"${FILESDIR}/simdjson-1.0.0-tests.patch"
+)
+
+DOCS=(
+	AUTHORS
+	CONTRIBUTING.md
+	CONTRIBUTORS
+	HACKING.md
+	README.md
+)
+
+src_prepare() {
+	if use test; then
+		mv "${WORKDIR}/${PN}-data-${DATA_HASH}" "${S}/dependencies/${PN}-data" || die
+	fi
+
+	sed -e 's:-Werror ::' -i cmake/developer-options.cmake || die
+	sed -e "s:^c++ :$(tc-getCXX) :" -i singleheader/README.md || die
+	mv tools/{,simd}jsonpointer.cpp || die
+	cmake_src_prepare
+}
+
+src_configure() {
+	local -a mycmakeargs=(
+		-DSIMDJSON_ENABLE_THREADS=ON
+	)
+	use test && mycmakeargs+=(
+		-DSIMDJSON_TESTS=ON
+	)
+
+	if use tools; then
+		mycmakeargs+=(
+			-DSIMDJSON_DEVELOPER_MODE=ON
+			-DSIMDJSON_ALLOW_DOWNLOADS=OFF
+			-DSIMDJSON_GOOGLE_BENCHMARKS=OFF
+			-DSIMDJSON_COMPETITION=OFF
+			-DSIMDJSON_TOOLS=ON
+		)
+	elif ! use test; then
+		mycmakeargs+=(
+			-DSIMDJSON_DEVELOPER_MODE=OFF
+		)
+	fi
+
+	cmake_src_configure
+}
-- 
cgit v1.2.3