From 93a93e9a3b53c1a73142a305ea1f8136846942ee Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 22 Dec 2021 14:08:05 +0000
Subject: gentoo resync : 22.12.2021

---
 dev-libs/satyr/satyr-0.39.ebuild | 101 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 101 insertions(+)
 create mode 100644 dev-libs/satyr/satyr-0.39.ebuild

(limited to 'dev-libs/satyr/satyr-0.39.ebuild')

diff --git a/dev-libs/satyr/satyr-0.39.ebuild b/dev-libs/satyr/satyr-0.39.ebuild
new file mode 100644
index 000000000000..754906da9469
--- /dev/null
+++ b/dev-libs/satyr/satyr-0.39.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{7..10} )
+
+inherit autotools multiprocessing python-r1
+
+DESCRIPTION="Satyr is a collection of low-level algorithms for program failure processing"
+HOMEPAGE="https://github.com/abrt/satyr"
+SRC_URI="https://github.com/abrt/${PN}/archive/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0/4"
+
+IUSE="python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	python? ( ${PYTHON_DEPS} )
+	>=dev-libs/elfutils-0.158
+	dev-libs/glib:2
+	dev-libs/json-c:=
+	dev-libs/nettle:=
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	dev-util/gperf
+"
+
+src_prepare() {
+	default
+	./gen-version || die # Needs to be run before full autoreconf
+	eautoreconf
+	use python && python_copy_sources
+}
+
+src_configure() {
+	use python && python_setup
+
+	local myargs=(
+		--localstatedir="${EPREFIX}/var"
+		--without-rpm
+		$(usex python "--with-python3" "--without-python3")
+	)
+
+	if use python; then
+		python_configure() {
+			econf "${myargs[@]}"
+		}
+		python_foreach_impl run_in_build_dir python_configure
+	else
+		econf "${myargs[@]}"
+	fi
+}
+
+src_compile() {
+	if use python; then
+		python_foreach_impl run_in_build_dir default
+	else
+		default
+	fi
+
+}
+
+src_test() {
+	local extra_args
+
+	# In order to pass --jobs to the test runner
+	run_tests() {
+		cd tests || die
+		emake testsuite
+		./testsuite --jobs=$(makeopts_jobs) ${extra_args[@]} $@
+
+		# Only run the python bindings tests for other python impls
+		extra_args=('-k' 'python3_bindings.*')
+	}
+
+	if use python; then
+		python_foreach_impl run_in_build_dir run_tests
+	else
+		run_tests SKIP_PYTHON3=yes
+	fi
+}
+
+src_install() {
+	if use python; then
+		python_install() {
+			default
+			python_optimize
+		}
+		python_foreach_impl run_in_build_dir python_install
+	else
+		default
+	fi
+
+	find "${D}" -name '*.la' -type f -delete || die
+}
-- 
cgit v1.2.3