From f617f04203a0968020e5a7252e865803636af918 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 10 Mar 2024 06:44:55 +0000
Subject: gentoo auto-resync : 10:03:2024 - 06:44:55

---
 dev-libs/rocr-runtime/rocr-runtime-5.7.1-r2.ebuild | 62 ++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 dev-libs/rocr-runtime/rocr-runtime-5.7.1-r2.ebuild

(limited to 'dev-libs/rocr-runtime/rocr-runtime-5.7.1-r2.ebuild')

diff --git a/dev-libs/rocr-runtime/rocr-runtime-5.7.1-r2.ebuild b/dev-libs/rocr-runtime/rocr-runtime-5.7.1-r2.ebuild
new file mode 100644
index 000000000000..00615488c2d2
--- /dev/null
+++ b/dev-libs/rocr-runtime/rocr-runtime-5.7.1-r2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LLVM_MAX_SLOT=17
+
+inherit cmake flag-o-matic llvm
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/RadeonOpenCompute/ROCR-Runtime/"
+	inherit git-r3
+	S="${WORKDIR}/${P}/src"
+else
+	SRC_URI="https://github.com/RadeonOpenCompute/ROCR-Runtime/archive/rocm-${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/ROCR-Runtime-rocm-${PV}/src"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Radeon Open Compute Runtime"
+HOMEPAGE="https://github.com/RadeonOpenCompute/ROCR-Runtime"
+PATCHES=(
+	"${FILESDIR}/${PN}-4.3.0_no-aqlprofiler.patch"
+	"${FILESDIR}/${PN}-5.7.1-extend-isa-compatibility-check.patch"
+	"${FILESDIR}/${PN}-5.7.1-musl.patch"
+)
+
+LICENSE="MIT"
+SLOT="0/$(ver_cut 1-2)"
+IUSE="debug"
+
+COMMON_DEPEND="dev-libs/elfutils
+	x11-libs/libdrm"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/roct-thunk-interface-${PV}
+	>=dev-libs/rocm-device-libs-${PV}
+	sys-devel/clang:${LLVM_MAX_SLOT}=
+	sys-devel/lld:${LLVM_MAX_SLOT}="
+RDEPEND="${DEPEND}"
+BDEPEND="app-editors/vim-core"
+	# vim-core is needed for "xxd"
+
+src_prepare() {
+	# ... otherwise system llvm/clang is used ...
+	sed -e "s:find_package(Clang REQUIRED HINTS \${CMAKE_INSTALL_PREFIX}/llvm \${CMAKE_PREFIX_PATH}/llvm PATHS /opt/rocm/llvm ):find_package(Clang REQUIRED HINTS /usr/lib/llvm/roc ):" -i image/blit_src/CMakeLists.txt || die
+
+	# Gentoo installs "*.bc" to "/usr/lib" instead of a "[path]/bitcode" directory ...
+	sed -e "s:-O2:--rocm-path=${EPREFIX}/usr/lib/ -O2:" -i image/blit_src/CMakeLists.txt || die
+
+	# internal version depends on git being present and random weird magic, otherwise fallback to incoherent default value
+	# fix default value to be more better
+
+	sed -i -e "s:1.7.0:${PV}:" CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	use debug || append-cxxflags "-DNDEBUG"
+	local mycmakeargs=( -DINCLUDE_PATH_COMPATIBILITY=OFF )
+	cmake_src_configure
+}
-- 
cgit v1.2.3