From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 dev-libs/re2/re2-0.2017.03.01.ebuild | 52 ++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 dev-libs/re2/re2-0.2017.03.01.ebuild

(limited to 'dev-libs/re2/re2-0.2017.03.01.ebuild')

diff --git a/dev-libs/re2/re2-0.2017.03.01.ebuild b/dev-libs/re2/re2-0.2017.03.01.ebuild
new file mode 100644
index 000000000000..0410c18f841f
--- /dev/null
+++ b/dev-libs/re2/re2-0.2017.03.01.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit multilib-minimal toolchain-funcs
+
+# Different date format used upstream.
+RE2_VER=${PV#0.}
+RE2_VER=${RE2_VER//./-}
+
+DESCRIPTION="An efficent, principled regular expression library"
+HOMEPAGE="https://github.com/google/re2"
+SRC_URI="https://github.com/google/re2/archive/${RE2_VER}.tar.gz -> re2-${RE2_VER}.tar.gz"
+
+LICENSE="BSD"
+# NOTE: Always run libre2 through abi-compliance-checker!
+# https://abi-laboratory.pro/tracker/timeline/re2/
+SONAME="gentoo-2017-03-01"
+SLOT="0/${SONAME}"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="icu"
+
+RDEPEND="icu? ( dev-libs/icu:0=[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	icu? ( virtual/pkgconfig )"
+
+S="${WORKDIR}/re2-${RE2_VER}"
+
+DOCS=( AUTHORS CONTRIBUTORS README doc/syntax.txt )
+HTML_DOCS=( doc/syntax.html )
+
+src_prepare() {
+	default
+	grep -qv '^SONAME=0$' Makefile || die "Check SONAME in Makefile"
+	if use icu; then
+		sed -i -e 's:^# \(\(CC\|LD\)ICU=.*\):\1:' Makefile || die
+	fi
+	multilib_copy_sources
+}
+
+src_configure() {
+	tc-export AR CXX NM
+}
+
+multilib_src_compile() {
+	emake SONAME="${SONAME}"
+}
+
+multilib_src_install() {
+	emake SONAME="${SONAME}" DESTDIR="${D}" prefix="${EPREFIX}/usr" libdir="\$(exec_prefix)/$(get_libdir)" install
+}
-- 
cgit v1.2.3