From 8376ef56580626e9c0f796d5b85b53a0a1c7d5f5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 14 Jul 2018 21:03:06 +0100
Subject: gentoo resync : 14.07.2018

---
 dev-libs/re2/re2-0.2016.11.01-r1.ebuild | 52 +++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 dev-libs/re2/re2-0.2016.11.01-r1.ebuild

(limited to 'dev-libs/re2/re2-0.2016.11.01-r1.ebuild')

diff --git a/dev-libs/re2/re2-0.2016.11.01-r1.ebuild b/dev-libs/re2/re2-0.2016.11.01-r1.ebuild
new file mode 100644
index 000000000000..e5a491a41c76
--- /dev/null
+++ b/dev-libs/re2/re2-0.2016.11.01-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit multilib-minimal toolchain-funcs
+
+# Different date format used upstream.
+RE2_VER=${PV#0.}
+RE2_VER=${RE2_VER//./-}
+
+DESCRIPTION="An efficent, principled regular expression library"
+HOMEPAGE="https://github.com/google/re2"
+SRC_URI="https://github.com/google/re2/archive/${RE2_VER}.tar.gz -> re2-${RE2_VER}.tar.gz"
+
+LICENSE="BSD"
+# NOTE: Always run libre2 through abi-compliance-checker!
+# https://abi-laboratory.pro/tracker/timeline/re2/
+SONAME="gentoo-2016-09-01"
+SLOT="0/${SONAME}"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="icu"
+
+RDEPEND="icu? ( dev-libs/icu:0=[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	icu? ( virtual/pkgconfig )"
+
+S="${WORKDIR}/re2-${RE2_VER}"
+
+DOCS=( AUTHORS CONTRIBUTORS README doc/syntax.txt )
+HTML_DOCS=( doc/syntax.html )
+
+src_prepare() {
+	default
+	grep -qv '^SONAME=0$' Makefile || die "Check SONAME in Makefile"
+	if use icu; then
+		sed -i -e 's:^# \(\(CC\|LD\)ICU=.*\):\1:' Makefile || die
+	fi
+	multilib_copy_sources
+}
+
+src_configure() {
+	tc-export AR CXX NM
+}
+
+multilib_src_compile() {
+	emake SONAME="${SONAME}"
+}
+
+multilib_src_install() {
+	emake SONAME="${SONAME}" DESTDIR="${D}" prefix="${EPREFIX}/usr" libdir="\$(exec_prefix)/$(get_libdir)" install
+}
-- 
cgit v1.2.3