From 57dbe782fa3930bfa59520388f90ca4c2f037785 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 13 Sep 2023 10:44:02 +0100
Subject: gentoo auto-resync : 13:09:2023 - 10:44:02

---
 dev-libs/quazip/Manifest             |  1 +
 dev-libs/quazip/quazip-1.4-r1.ebuild | 89 ++++++++++++++++++++++++++++++++++++
 2 files changed, 90 insertions(+)
 create mode 100644 dev-libs/quazip/quazip-1.4-r1.ebuild

(limited to 'dev-libs/quazip')

diff --git a/dev-libs/quazip/Manifest b/dev-libs/quazip/Manifest
index 9348b10473d2..62f21d464fa0 100644
--- a/dev-libs/quazip/Manifest
+++ b/dev-libs/quazip/Manifest
@@ -7,5 +7,6 @@ DIST quazip-1.4.tar.gz 157819 BLAKE2B bb0ec2ebd31d6ce5e2a19fc1b13570d57aa1438ff1
 EBUILD quazip-1.2.ebuild 941 BLAKE2B fdfbd8cc0cb2a17409081c4de485bd573a1ff3145778c71d57e618dcf860638b8bc85923a624e3ef36b1f865b576c65183ed82229dc0cd378f159372b8c80fb6 SHA512 bde570eb2fd7d7944db9cad35fe888044c26c602ddbf31ce4782161e85620db781b46ba951d499519409a00464fdcb84e63c4e6c1e76818ad886fced3fddf46c
 EBUILD quazip-1.3-r2.ebuild 1695 BLAKE2B af2209f84693bf4b38cc4bd89cc24ef9f80349498dda023df0b35eecceee666129c8214937c1672a7f6544b8a6791600c7fc11a580eb8e5a41d32b8e6d7b3b90 SHA512 f98cb7714bb0f50c7cfa842112c25c8786a65357af17ea66fd48ca592c1e0f0ef9a7e6c618d1a22670f7beb8e17fd99eb5abffaed1e81b5d04a675f97ddfc6ce
 EBUILD quazip-1.3-r3.ebuild 1697 BLAKE2B 40cbdbe7a36872b6e657cf6d2a4564ba3c09012c641041c5cb21986e62f38c5e489c84b38da47ff7c68b1e28f72547538f3743a7e341db349441b47bbfc1708a SHA512 efaace1454c7388f524d9c3c352d064dba27378d9769812043107699d30319501a7be462e02fb32092a0effed1000c55069e0341dc45a443c0ef4ebe894ad752
+EBUILD quazip-1.4-r1.ebuild 1829 BLAKE2B dad35ab709f6969be57a481353f39b88631221edc74c0aac387b9169462f47cc0c7e69eab5bf7dd1ff62bfb34272646e3f7b85f9a4ca13b1f44157f768d5bbe8 SHA512 0235cd1a2af12b89e52345b5e56c98e555ee275c229f69d62fd2f7138ae087b9ed52672131bae20167a59df3b36cac953cb844d679fb5049336d72e95dd5ad40
 EBUILD quazip-1.4.ebuild 1785 BLAKE2B 95806098fa03d5cc2f46af6127cf047c27e40ae8cefd8a3121900752b721b66c858db0d8b52bdbb0c1bbab32e416bbcf8420404493ce1c2274cd4288d8caa793 SHA512 cb37d5ab2e51017424cc556f242f4e43d82c47cd599689c68bab49a6f296f77f66dbb2c12c90fb105d5ec5671361335bc8675e3bbeef891e6affc5f8b9d96f4f
 MISC metadata.xml 461 BLAKE2B 24ee9745d2baa54233f3cea1e7ec426e83ddbf458e63e679f204014ba4d8dd971c0da5876db9adf2b41fbda1239ff89752eebd30fe6a8da179f34274501507cc SHA512 d6d54cd6e2a16ab151dc987dd75772d996f733f7e5212cce7a73d9ed2b75721230b9295476bf6c5680343e9ce02cfafa7d2b667afc5597d770c66c96a8474956
diff --git a/dev-libs/quazip/quazip-1.4-r1.ebuild b/dev-libs/quazip/quazip-1.4-r1.ebuild
new file mode 100644
index 000000000000..fc7a353e473e
--- /dev/null
+++ b/dev-libs/quazip/quazip-1.4-r1.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake multibuild
+
+DESCRIPTION="Simple C++ wrapper over Gilles Vollant's ZIP/UNZIP package"
+HOMEPAGE="https://stachenov.github.io/quazip/"
+SRC_URI="https://github.com/stachenov/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1-with-linking-exception"
+# SONAME of libquazip1-qt5.so, check QUAZIP_LIB_SOVERSION in CMakeLists.txt
+SLOT="0/1.4"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+IUSE="bzip2 +qt5 qt6 test"
+REQUIRED_USE="|| ( qt5 qt6 )"
+
+RESTRICT="!test? ( test )"
+
+# bzip2 is linked against, so no app-alternatives
+COMMON_DEPEND="
+	bzip2? ( app-arch/bzip2:= )
+	qt5? ( dev-qt/qtcore:5 )
+	qt6? (
+		dev-qt/qtbase:6
+		dev-qt/qt5compat:6
+	)
+	sys-libs/zlib[minizip]
+"
+DEPEND="${COMMON_DEPEND}
+	test? (
+		qt5? (
+			dev-qt/qtnetwork:5
+			dev-qt/qttest:5
+		)
+		qt6? (
+			dev-qt/qtbase:6[network]
+		)
+	)
+"
+RDEPEND="${COMMON_DEPEND}"
+
+PATCHES=(
+	# Use CTest module provided BUILD_TESTING
+	"${FILESDIR}/${P}-cmake.patch"
+)
+
+pkg_setup() {
+	MULTIBUILD_VARIANTS=( $(usev qt5) $(usev qt6) )
+}
+
+src_configure() {
+	my_src_configure() {
+		local mycmakeargs=(
+			-DBUILD_TESTING=$(usex test)
+			-DQUAZIP_BZIP2=$(usex bzip2)
+		)
+		if [[ ${MULTIBUILD_VARIANT} = qt5 ]]; then
+			mycmakeargs+=(
+				-DQUAZIP_QT_MAJOR_VERSION=5
+			)
+		elif [[ ${MULTIBUILD_VARIANT} = qt6 ]]; then
+			mycmakeargs+=(
+				-DQUAZIP_QT_MAJOR_VERSION=6
+			)
+		fi
+		cmake_src_configure
+	}
+
+	multibuild_foreach_variant my_src_configure
+}
+
+src_compile() {
+	my_src_compile() {
+		cmake_src_compile
+		use test && cmake_build qztest
+	}
+
+	multibuild_foreach_variant my_src_compile
+}
+
+src_test() {
+	multibuild_foreach_variant cmake_src_test
+}
+
+src_install() {
+	multibuild_foreach_variant cmake_src_install
+}
-- 
cgit v1.2.3