From 7ae4e1d32a98b596d483a19ed94a21b560eb595d Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 24 Oct 2022 21:52:37 +0100
Subject: gentoo auto-resync : 24:10:2022 - 21:52:37

---
 dev-libs/libzia/libzia-4.37.ebuild | 54 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 dev-libs/libzia/libzia-4.37.ebuild

(limited to 'dev-libs/libzia/libzia-4.37.ebuild')

diff --git a/dev-libs/libzia/libzia-4.37.ebuild b/dev-libs/libzia/libzia-4.37.ebuild
new file mode 100644
index 000000000000..ab1b7f2cd743
--- /dev/null
+++ b/dev-libs/libzia/libzia-4.37.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools flag-o-matic
+
+DESCRIPTION="Platform abstraction code for tucnak package"
+HOMEPAGE="http://tucnak.nagano.cz"
+SRC_URI="http://tucnak.nagano.cz/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ftdi"
+
+RDEPEND="dev-libs/glib:2
+	x11-libs/gtk+:2
+	media-libs/libsdl
+	media-libs/libpng:0
+	ftdi? ( dev-embedded/libftdi:1 )
+	elibc_musl? ( sys-libs/libunwind )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+MAKEOPTS+=" -j1"
+
+src_prepare() {
+	eapply_user
+	sed -i -e "s/docsdir/#docsdir/g" \
+		-e "s/docs_/#docs_/g" Makefile.am || die
+
+	# Fix QA-Warning "QA Notice: pkg-config files with wrong LDFLAGS detected"
+	sed -i -e 's/@LDFLAGS@//' libzia.pc.in || die
+
+	# fix build for MUSL (bug #832235)
+	if use elibc_musl ; then
+		sed -i -e "s/ backtrace(/ unw_backtrace(/" src/zbfd.c || die
+	fi
+	eautoreconf
+}
+
+src_configure() {
+	use elibc_musl && append-libs -lunwind
+	econf \
+		$(use_with ftdi) --with-sdl \
+		--with-png --without-bfd \
+		--disable-static
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	find "${D}" -name '*.la' -type f -delete || die
+}
-- 
cgit v1.2.3