From d0bb3151c569ab6e40c84c177f43bff3c7ce4780 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 25 Aug 2023 15:54:35 +0100
Subject: gentoo auto-resync : 25:08:2023 - 15:54:35

---
 dev-libs/libxmlb/libxmlb-0.3.14.ebuild | 65 ++++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 dev-libs/libxmlb/libxmlb-0.3.14.ebuild

(limited to 'dev-libs/libxmlb/libxmlb-0.3.14.ebuild')

diff --git a/dev-libs/libxmlb/libxmlb-0.3.14.ebuild b/dev-libs/libxmlb/libxmlb-0.3.14.ebuild
new file mode 100644
index 000000000000..c6599b5571e7
--- /dev/null
+++ b/dev-libs/libxmlb/libxmlb-0.3.14.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit meson python-any-r1
+
+DESCRIPTION="Library to help create and query binary XML blobs"
+HOMEPAGE="https://github.com/hughsie/libxmlb"
+SRC_URI="https://github.com/hughsie/libxmlb/archive/${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="LGPL-2.1+"
+SLOT="0/2" # libxmlb.so version
+
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="doc introspection stemmer test +zstd"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-arch/xz-utils
+	dev-libs/glib:2
+	sys-apps/util-linux
+	stemmer? ( dev-libs/snowball-stemmer:= )
+	zstd? ( app-arch/zstd:= )
+"
+
+DEPEND="
+	${RDEPEND}
+	doc? ( dev-util/gtk-doc )
+	introspection? ( dev-libs/gobject-introspection )
+"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	>=dev-util/meson-0.47.0
+	virtual/pkgconfig
+	introspection? (
+		$(python_gen_any_dep 'dev-python/setuptools[${PYTHON_USEDEP}]')
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.3.12-no_installed_tests.patch
+)
+
+python_check_deps() {
+	python_has_version -b "dev-python/setuptools[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use doc gtkdoc)
+		$(meson_use introspection)
+		$(meson_use stemmer)
+		$(meson_use test tests)
+		$(meson_use zstd)
+	)
+	meson_src_configure
+}
-- 
cgit v1.2.3