From 068424b26532f3551a81421a9be67ed206e5c11a Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 11 Aug 2021 07:02:28 +0100
Subject: gentoo resync : 11.08.2021

---
 dev-libs/libuv/libuv-1.42.0.ebuild | 58 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 dev-libs/libuv/libuv-1.42.0.ebuild

(limited to 'dev-libs/libuv/libuv-1.42.0.ebuild')

diff --git a/dev-libs/libuv/libuv-1.42.0.ebuild b/dev-libs/libuv/libuv-1.42.0.ebuild
new file mode 100644
index 000000000000..f1d10ed56e94
--- /dev/null
+++ b/dev-libs/libuv/libuv-1.42.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools multilib-minimal
+
+DESCRIPTION="Cross-platform asychronous I/O"
+HOMEPAGE="https://github.com/libuv/libuv"
+
+if [[ ${PV} = 9999* ]]; then
+	EGIT_REPO_URI="https://github.com/libuv/libuv.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/libuv/libuv/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+fi
+
+LICENSE="BSD BSD-2 ISC MIT"
+SLOT="0/1"
+
+BDEPEND="
+	sys-devel/libtool
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+
+	echo "m4_define([UV_EXTRA_AUTOMAKE_FLAGS], [serial-tests])" \
+		> m4/libuv-extra-automake-flags.m4 || die
+
+	if [[ ${CHOST} == *-darwin* && ${CHOST##*darwin} -le 9 ]] ; then
+		eapply "${FILESDIR}"/${PN}-1.41.0-darwin.patch
+	fi
+
+	# upstream fails to ship a configure script
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--disable-static
+		cc_cv_cflags__g=no
+	)
+
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_test() {
+	cp -pPR "${S}"/test/fixtures "${BUILD_DIR}"/test/fixtures || die
+	default
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3