From fcc5224904648a8e6eb528d7603154160a20022f Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 2 Feb 2022 01:39:05 +0000
Subject: gentoo resync : 02.02.2022

---
 dev-libs/libutf8proc/libutf8proc-2.7.0.ebuild | 56 +++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 dev-libs/libutf8proc/libutf8proc-2.7.0.ebuild

(limited to 'dev-libs/libutf8proc/libutf8proc-2.7.0.ebuild')

diff --git a/dev-libs/libutf8proc/libutf8proc-2.7.0.ebuild b/dev-libs/libutf8proc/libutf8proc-2.7.0.ebuild
new file mode 100644
index 000000000000..7e8a223a3271
--- /dev/null
+++ b/dev-libs/libutf8proc/libutf8proc-2.7.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+USE_RUBY="ruby25 ruby26 ruby27"
+
+inherit ruby-single toolchain-funcs
+
+DESCRIPTION="A clean C Library for processing UTF-8 Unicode data"
+HOMEPAGE="https://github.com/JuliaStrings/utf8proc"
+SRC_URI="https://github.com/JuliaStrings/${PN#lib}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	cjk? ( https://dev.gentoo.org/~hattya/distfiles/${PN}-EastAsianWidth-14.0.0.xz )"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="cjk static-libs test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? (
+		=app-i18n/unicode-data-14.0*
+		${RUBY_DEPS}
+	)"
+S="${WORKDIR}/${P#lib}"
+
+src_prepare() {
+	if use cjk; then
+		einfo "Modifying East Asian Ambiguous (A) as wide ..."
+		cp "${WORKDIR}"/${PN}-EastAsianWidth-14.0.0 ${PN#lib}_data.c || die
+	fi
+
+	default
+}
+
+src_compile() {
+	emake \
+		AR="$(tc-getAR)" \
+		CC="$(tc-getCC)" \
+		prefix="/usr" \
+		libdir="${EPREFIX}/usr/$(get_libdir)"
+}
+
+src_install() {
+	emake \
+		DESTDIR="${ED}" \
+		prefix="/usr" \
+		libdir="/usr/$(get_libdir)" \
+		install
+	use static-libs || find "${ED}" -name '*.a' -delete || die
+}
+
+src_test() {
+	cp "${EPREFIX}"/usr/share/unicode-data/{DerivedCoreProperties,{Normalization,auxiliary/GraphemeBreak}Test}.txt data || die
+
+	emake CC="$(tc-getCC)" check
+}
-- 
cgit v1.2.3