From d99093fb4bb5652015c06274d64083daa2439e4f Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 3 Mar 2021 10:28:17 +0000
Subject: gentoo resync : 03.03.2021

---
 dev-libs/libutf8proc/libutf8proc-2.6.1.ebuild | 50 +++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 dev-libs/libutf8proc/libutf8proc-2.6.1.ebuild

(limited to 'dev-libs/libutf8proc/libutf8proc-2.6.1.ebuild')

diff --git a/dev-libs/libutf8proc/libutf8proc-2.6.1.ebuild b/dev-libs/libutf8proc/libutf8proc-2.6.1.ebuild
new file mode 100644
index 000000000000..323f38181fb6
--- /dev/null
+++ b/dev-libs/libutf8proc/libutf8proc-2.6.1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit toolchain-funcs
+
+DESCRIPTION="A clean C Library for processing UTF-8 Unicode data"
+HOMEPAGE="https://github.com/JuliaStrings/utf8proc"
+SRC_URI="https://github.com/JuliaStrings/${PN#lib}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	cjk? ( https://dev.gentoo.org/~hattya/distfiles/${PN}-EastAsianWidth-13.0.0-r1.xz )"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux"
+IUSE="cjk static-libs test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? ( =app-i18n/unicode-data-13.0* )"
+S="${WORKDIR}/${P#lib}"
+
+src_prepare() {
+	if use cjk; then
+		einfo "Modifying East Asian Ambiguous (A) as wide ..."
+		cp "${WORKDIR}"/${PN}-EastAsianWidth-13.0.0-r1 ${PN#lib}_data.c || die
+	fi
+
+	default
+}
+
+src_compile() {
+	emake \
+		AR="$(tc-getAR)" \
+		CC="$(tc-getCC)"
+}
+
+src_install() {
+	emake \
+		DESTDIR="${ED}" \
+		prefix="/usr" \
+		libdir="/usr/$(get_libdir)" \
+		install
+	use static-libs || find "${ED}" -name '*.a' -delete || die
+}
+
+src_test() {
+	cp "${EPREFIX}"/usr/share/unicode-data/{DerivedCoreProperties,{Normalization,auxiliary/GraphemeBreak}Test}.txt data || die
+
+	emake CC="$(tc-getCC)" check
+}
-- 
cgit v1.2.3