From 99abbc5e5a6ecd3fc981b45646fd8cb5d320377b Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 24 Feb 2018 19:58:07 +0000
Subject: gentoo resync : 24.02.2018

---
 dev-libs/librdkafka/librdkafka-0.11.3-r1.ebuild | 73 +++++++++++++++++++++++++
 1 file changed, 73 insertions(+)
 create mode 100644 dev-libs/librdkafka/librdkafka-0.11.3-r1.ebuild

(limited to 'dev-libs/librdkafka/librdkafka-0.11.3-r1.ebuild')

diff --git a/dev-libs/librdkafka/librdkafka-0.11.3-r1.ebuild b/dev-libs/librdkafka/librdkafka-0.11.3-r1.ebuild
new file mode 100644
index 000000000000..f7ec851be536
--- /dev/null
+++ b/dev-libs/librdkafka/librdkafka-0.11.3-r1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit toolchain-funcs
+
+DESCRIPTION="Apache Kafka C/C++ client library"
+HOMEPAGE="https://github.com/edenhill/librdkafka"
+
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/edenhill/${PN}.git"
+
+	inherit git-r3
+else
+	SRC_URI="https://github.com/edenhill/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="amd64 ~arm ~arm64 ~hppa ~ppc x86"
+
+	PATCHES=( "${FILESDIR}"/${P}-fix-memory-leak-issue1534.patch )
+fi
+
+LICENSE="BSD-2"
+
+# subslot = soname version
+SLOT="0/1"
+
+IUSE="lz4 sasl ssl static-libs"
+
+RDEPEND="
+	lz4? ( app-arch/lz4:= )
+	sasl? ( dev-libs/cyrus-sasl:= )
+	ssl? ( dev-libs/openssl:0= )
+	sys-libs/zlib
+"
+
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+"
+
+src_configure() {
+	tc-export CC CXX LD NM OBJDUMP PKG_CONFIG STRIP
+
+	local myeconf=(
+		--no-cache
+		--no-download
+		--disable-debug-symbols
+		$(use_enable lz4)
+		$(use_enable sasl)
+		$(usex static-libs '--enable-static' '')
+		$(use_enable ssl)
+	)
+
+	econf ${myeconf[@]}
+}
+
+src_test() {
+	emake -C tests run_local
+}
+
+src_install() {
+	local DOCS=(
+		README.md
+		CONFIGURATION.md
+		INTRODUCTION.md
+	)
+
+	default
+
+	if ! use static-libs; then
+		find "${ED}"usr/lib* -name '*.la' -o -name '*.a' -delete || die
+	fi
+}
-- 
cgit v1.2.3