From 40aaaa64e86ba6710bbeb31c4615a6ce80e75e11 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 28 Apr 2021 20:21:43 +0100
Subject: gentoo resync : 28.04.2021

---
 dev-libs/libqtxdg/libqtxdg-3.7.1.ebuild | 56 +++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 dev-libs/libqtxdg/libqtxdg-3.7.1.ebuild

(limited to 'dev-libs/libqtxdg/libqtxdg-3.7.1.ebuild')

diff --git a/dev-libs/libqtxdg/libqtxdg-3.7.1.ebuild b/dev-libs/libqtxdg/libqtxdg-3.7.1.ebuild
new file mode 100644
index 000000000000..ef6c277b7552
--- /dev/null
+++ b/dev-libs/libqtxdg/libqtxdg-3.7.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake optfeature virtualx
+
+DESCRIPTION="Qt Implementation of XDG Standards"
+HOMEPAGE="https://lxqt.github.io/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+fi
+
+LICENSE="LGPL-2.1+ Nokia-Qt-LGPL-Exception-1.1"
+SLOT="0"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	>=dev-util/lxqt-build-tools-0.9.0
+	virtual/pkgconfig
+"
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5=
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	x11-misc/xdg-utils
+"
+DEPEND="${RDEPEND}
+	test? ( dev-qt/qttest:5 )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTS=$(usex test)
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	# Tests don't work with C
+	LC_ALL=en_US.utf8 virtx cmake_src_test
+}
+
+pkg_postinst() {
+	! has_version lxqt-base/lxqt-meta && optfeature "features that require a terminal emulator" x11-terms/xterm
+}
-- 
cgit v1.2.3