From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 dev-libs/libnl/libnl-3.2.29.ebuild | 114 +++++++++++++++++++++++++++++++++++++
 1 file changed, 114 insertions(+)
 create mode 100644 dev-libs/libnl/libnl-3.2.29.ebuild

(limited to 'dev-libs/libnl/libnl-3.2.29.ebuild')

diff --git a/dev-libs/libnl/libnl-3.2.29.ebuild b/dev-libs/libnl/libnl-3.2.29.ebuild
new file mode 100644
index 000000000000..55886ce41b3e
--- /dev/null
+++ b/dev-libs/libnl/libnl-3.2.29.ebuild
@@ -0,0 +1,114 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+DISTUTILS_OPTIONAL=1
+inherit distutils-r1 eutils libtool multilib multilib-minimal
+
+LIBNL_P=${P/_/-}
+LIBNL_DIR=${PV/_/}
+LIBNL_DIR=${LIBNL_DIR//./_}
+
+DESCRIPTION="Libraries providing APIs to netlink protocol based Linux kernel interfaces"
+HOMEPAGE="http://www.infradead.org/~tgr/libnl/ https://github.com/thom311/libnl"
+SRC_URI="
+	https://github.com/thom311/${PN}/releases/download/${PN}${LIBNL_DIR}/${P/_rc/-rc}.tar.gz
+	https://dev.gentoo.org/~jer/libnl-3.2.28-in6.patch.xz
+"
+LICENSE="LGPL-2.1 utils? ( GPL-2 )"
+SLOT="3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="static-libs python utils"
+
+RDEPEND="
+	python? ( ${PYTHON_DEPS} )
+	abi_x86_32? (
+		!<=app-emulation/emul-linux-x86-baselibs-20140508-r5
+		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
+	)
+"
+DEPEND="
+	${RDEPEND}
+	python? ( dev-lang/swig )
+	sys-devel/bison
+	sys-devel/flex
+"
+
+REQUIRED_USE="
+	python? ( ${PYTHON_REQUIRED_USE} )
+"
+
+DOCS=(
+	ChangeLog
+)
+
+S=${WORKDIR}/${LIBNL_P}
+
+MULTILIB_WRAPPED_HEADERS=(
+	# we do not install CLI stuff for non-native
+	/usr/include/libnl3/netlink/cli/addr.h
+	/usr/include/libnl3/netlink/cli/class.h
+	/usr/include/libnl3/netlink/cli/cls.h
+	/usr/include/libnl3/netlink/cli/ct.h
+	/usr/include/libnl3/netlink/cli/exp.h
+	/usr/include/libnl3/netlink/cli/link.h
+	/usr/include/libnl3/netlink/cli/neigh.h
+	/usr/include/libnl3/netlink/cli/qdisc.h
+	/usr/include/libnl3/netlink/cli/route.h
+	/usr/include/libnl3/netlink/cli/rule.h
+	/usr/include/libnl3/netlink/cli/tc.h
+	/usr/include/libnl3/netlink/cli/utils.h
+)
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.1-vlan-header.patch
+	"${WORKDIR}"/${PN}-3.2.28-in6.patch
+)
+
+src_prepare() {
+	default
+
+	elibtoolize
+
+	if use python; then
+		cd "${S}"/python || die
+		distutils-r1_src_prepare
+	fi
+
+	# out-of-source build broken
+	# https://github.com/thom311/libnl/pull/58
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	econf \
+		--disable-silent-rules \
+		$(use_enable static-libs static) \
+		$(multilib_native_use_enable utils cli)
+}
+
+multilib_src_compile() {
+	default
+
+	if multilib_is_native_abi && use python; then
+		cd python || die
+		distutils-r1_src_compile
+	fi
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+
+	if multilib_is_native_abi && use python; then
+		# Unset DOCS= since distutils-r1.eclass interferes
+		local DOCS=()
+		cd python || die
+		distutils-r1_src_install
+	fi
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files --modules
+}
-- 
cgit v1.2.3