From 40aaaa64e86ba6710bbeb31c4615a6ce80e75e11 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 28 Apr 2021 20:21:43 +0100
Subject: gentoo resync : 28.04.2021

---
 dev-libs/liblist/liblist-2.4-r1.ebuild | 51 ++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 dev-libs/liblist/liblist-2.4-r1.ebuild

(limited to 'dev-libs/liblist/liblist-2.4-r1.ebuild')

diff --git a/dev-libs/liblist/liblist-2.4-r1.ebuild b/dev-libs/liblist/liblist-2.4-r1.ebuild
new file mode 100644
index 000000000000..4ff0ef02da9f
--- /dev/null
+++ b/dev-libs/liblist/liblist-2.4-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Generic linked-list manipulation routines, plus queues and stacks"
+HOMEPAGE="http://ohnopub.net/liblist"
+SRC_URI="ftp://ohnopublishing.net/mirror/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~ppc ~ppc64 x86 ~amd64-linux"
+IUSE="doc examples"
+
+BDEPEND="
+	doc? (
+		dev-texlive/texlive-metapost
+		media-gfx/transfig
+		virtual/latex-base
+	)
+"
+
+src_configure() {
+	econf \
+		--disable-static \
+		$(use_enable doc docs) \
+		$(use_enable examples)
+}
+
+src_install() {
+	default
+
+	if use examples; then
+		docinto examples
+		dodoc examples/{*.c,Makefile,README}
+		docinto examples/cache
+		dodoc examples/cache/{*.c,README}
+	fi
+
+	docompress -x /usr/share/doc/${PF}/{list.0,paper.dvi,examples}
+
+	# no static archives
+	find "${ED}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	elog "Note that man pages for this package have been renamed to avoid"
+	elog "name collisions with some system functions. However, the libs"
+	elog "and header files have not been changed."
+	elog "The new names are liblist, lcache, liblist_queue, and liblist_stack."
+}
-- 
cgit v1.2.3