From 8376ef56580626e9c0f796d5b85b53a0a1c7d5f5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 14 Jul 2018 21:03:06 +0100
Subject: gentoo resync : 14.07.2018

---
 dev-libs/liblinear/liblinear-210-r1.ebuild | 64 ++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)
 create mode 100644 dev-libs/liblinear/liblinear-210-r1.ebuild

(limited to 'dev-libs/liblinear/liblinear-210-r1.ebuild')

diff --git a/dev-libs/liblinear/liblinear-210-r1.ebuild b/dev-libs/liblinear/liblinear-210-r1.ebuild
new file mode 100644
index 000000000000..ca03976be48a
--- /dev/null
+++ b/dev-libs/liblinear/liblinear-210-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit multilib toolchain-funcs
+
+DESCRIPTION="A Library for Large Linear Classification"
+HOMEPAGE="https://www.csie.ntu.edu.tw/~cjlin/liblinear/ https://github.com/cjlin1/liblinear"
+SRC_URI="https://github.com/cjlin1/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/3"
+KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86"
+IUSE="blas"
+
+RDEPEND="
+	blas? ( virtual/blas )
+"
+DEPEND="
+	${RDEPEND}
+	blas? ( virtual/pkgconfig )
+"
+
+src_prepare() {
+	sed -i \
+		-e '/^AR/s|=|?=|g' \
+		-e '/^RANLIB/s|=|?=|g' \
+		-e '/^CFLAGS/d;/^CXXFLAGS/d' \
+		blas/Makefile || die
+	sed -i \
+		-e 's|make|$(MAKE)|g' \
+		-e '/$(LIBS)/s|$(CFLAGS)|& $(LDFLAGS)|g' \
+		-e '/^CFLAGS/d;/^CXXFLAGS/d' \
+		-e 's|$${SHARED_LIB_FLAG}|& $(LDFLAGS)|g' \
+		Makefile || die
+	if use blas; then
+		sed -i -e 's:blas/blas.a::g' Makefile || die
+	fi
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		CXX="$(tc-getCXX)" \
+		CFLAGS="${CFLAGS} -fPIC" \
+		CXXFLAGS="${CXXFLAGS} -fPIC" \
+		AR="$(tc-getAR) rcv" \
+		RANLIB="$(tc-getRANLIB)" \
+		LIBS="$(usex blas "$( $(tc-getPKG_CONFIG) --libs blas )" blas/blas.a)" \
+		lib all
+}
+
+src_install() {
+	dolib ${PN}.so.3
+	dosym ${PN}.so.3 /usr/$(get_libdir)/${PN}.so
+
+	newbin predict ${PN}-predict
+	newbin train ${PN}-train
+
+	doheader linear.h
+
+	dodoc README
+}
-- 
cgit v1.2.3