From 3cf7c3ef441822c889356fd1812ebf2944a59851 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Tue, 25 Aug 2020 10:45:55 +0100
Subject: gentoo resync : 25.08.2020

---
 dev-libs/libintl/libintl-0.20.2.ebuild | 80 ++++++++++++++++++++++++++++++++++
 1 file changed, 80 insertions(+)
 create mode 100644 dev-libs/libintl/libintl-0.20.2.ebuild

(limited to 'dev-libs/libintl/libintl-0.20.2.ebuild')

diff --git a/dev-libs/libintl/libintl-0.20.2.ebuild b/dev-libs/libintl/libintl-0.20.2.ebuild
new file mode 100644
index 000000000000..381e47de63d1
--- /dev/null
+++ b/dev-libs/libintl/libintl-0.20.2.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# Note: Keep version bumps in sync with sys-devel/gettext.
+
+EAPI=7
+
+MY_P="gettext-${PV}"
+
+inherit multilib-minimal toolchain-funcs libtool usr-ldscript
+
+DESCRIPTION="the GNU international library (split out of gettext)"
+HOMEPAGE="https://www.gnu.org/software/gettext/"
+SRC_URI="mirror://gnu/gettext/${MY_P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
+IUSE="static-libs +threads"
+
+DEPEND=">=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]"
+# Block C libraries known to provide libintl.
+RDEPEND="${DEPEND}
+	!sys-libs/glibc
+	!sys-libs/musl
+	!<sys-devel/gettext-0.19.6-r1"
+
+S="${WORKDIR}/${MY_P}/gettext-runtime"
+
+src_prepare() {
+	default
+
+	# The libtool files are stored higher up, so make sure we run in the
+	# whole tree and not just the subdir we build.
+	elibtoolize "${WORKDIR}"
+}
+
+multilib_src_configure() {
+	local myconf=(
+		# Emacs support is now in a separate package.
+		--without-emacs
+		--without-lispdir
+		# Normally this controls nls behavior in general, but the libintl
+		# subdir is skipped unless this is explicitly set.  ugh.
+		--enable-nls
+		# This magic flag enables libintl.
+		--with-included-gettext
+		# The gettext package provides this library.
+		--disable-c++
+		--disable-libasprintf
+		# No java until someone cares.
+		--disable-java
+
+		$(use_enable static-libs static)
+		$(use_enable threads)
+	)
+	ECONF_SOURCE="${S}" econf "${myconf[@]}"
+}
+
+multilib_src_compile() {
+	# We only need things in the intl/ subdir.
+	emake -C intl
+}
+
+multilib_src_install() {
+	# We only need things in the intl/ subdir.
+	emake DESTDIR="${D}" install -C intl
+
+	gen_usr_ldscript -a intl
+}
+
+multilib_src_install_all() {
+	if ! use static-libs ; then
+		find "${ED}" -type f -name "*.la" -delete || die
+	fi
+
+	rm -r "${ED}"/usr/share/locale || die
+
+	dodoc AUTHORS ChangeLog NEWS README
+}
-- 
cgit v1.2.3