From 0922e7f160098c343e6e41a5e167a69b9e035db6 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 6 May 2023 05:33:06 +0100
Subject: gentoo auto-resync : 06:05:2023 - 05:33:06

---
 dev-libs/libevdev/libevdev-1.13.1.ebuild | 50 ++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 dev-libs/libevdev/libevdev-1.13.1.ebuild

(limited to 'dev-libs/libevdev/libevdev-1.13.1.ebuild')

diff --git a/dev-libs/libevdev/libevdev-1.13.1.ebuild b/dev-libs/libevdev/libevdev-1.13.1.ebuild
new file mode 100644
index 000000000000..0e89613cd1e8
--- /dev/null
+++ b/dev-libs/libevdev/libevdev-1.13.1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit meson-multilib python-any-r1
+
+DESCRIPTION="Handler library for evdev events"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libevdev/ https://gitlab.freedesktop.org/libevdev/libevdev"
+
+if [[ ${PV} == 9999* ]] ; then
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/libevdev/libevdev.git"
+	inherit git-r3
+else
+	SRC_URI="https://www.freedesktop.org/software/libevdev/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="doc test"
+
+DEPEND="test? ( dev-libs/check[${MULTILIB_USEDEP}] )"
+BDEPEND="
+	${PYTHON_DEPS}
+	doc? ( app-doc/doxygen )
+	virtual/pkgconfig
+"
+RESTRICT="!test? ( test )"
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_feature doc documentation)
+		$(meson_feature test tests)
+	)
+	meson_src_configure
+}
+
+multilib_src_test() {
+	meson_src_test -t 100
+}
+
+multilib_src_install_all() {
+	if use doc; then
+		local HTML_DOCS=( doc/html/. )
+		einstalldocs
+	fi
+}
-- 
cgit v1.2.3