From 844ae757702c53a56ee57056873a8204d256d47e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 19 Dec 2022 13:48:26 +0000
Subject: gentoo auto-resync : 19:12:2022 - 13:48:25

---
 .../libayatana-appindicator-0.5.91.ebuild          | 51 ++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 dev-libs/libayatana-appindicator/libayatana-appindicator-0.5.91.ebuild

(limited to 'dev-libs/libayatana-appindicator/libayatana-appindicator-0.5.91.ebuild')

diff --git a/dev-libs/libayatana-appindicator/libayatana-appindicator-0.5.91.ebuild b/dev-libs/libayatana-appindicator/libayatana-appindicator-0.5.91.ebuild
new file mode 100644
index 000000000000..906aef94b494
--- /dev/null
+++ b/dev-libs/libayatana-appindicator/libayatana-appindicator-0.5.91.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+VALA_USE_DEPEND="vapigen"
+
+inherit cmake vala virtualx
+
+DESCRIPTION="Ayatana Application Indicators (Shared Library)"
+HOMEPAGE="https://github.com/AyatanaIndicators/libayatana-appindicator"
+SRC_URI="https://github.com/AyatanaIndicators/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3 LGPL-2 LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.37:2
+	>=x11-libs/gtk+-3.24:3[introspection]
+	dev-libs/libdbusmenu[gtk3]
+	>=dev-libs/libayatana-indicator-0.8.4
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	$(vala_depend)
+	test? ( dev-util/dbus-test-runner )
+"
+
+src_prepare() {
+	vala_setup
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs+=(
+		-DVALA_COMPILER="${VALAC}"
+		-DVAPI_GEN="${VAPIGEN}"
+		-DENABLE_TESTS="$(usex test)"
+		-DENABLE_GTKDOC=OFF
+		-DENABLE_BINDINGS_MONO=OFF
+		-DFLAVOUR_GTK2=OFF
+		-DFLAVOUR_GTK3=ON
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	virtx cmake_src_test
+}
-- 
cgit v1.2.3