From 24d75f43d3d4caf76f2448bb277e89a3b3ae0d99 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 3 Aug 2022 13:48:30 +0100
Subject: gentoo auto-resync : 03.08.2022 - 13:48:05

---
 .../intel-compute-runtime-22.28.23726-r1.ebuild    | 79 ++++++++++++++++++++++
 1 file changed, 79 insertions(+)
 create mode 100644 dev-libs/intel-compute-runtime/intel-compute-runtime-22.28.23726-r1.ebuild

(limited to 'dev-libs/intel-compute-runtime/intel-compute-runtime-22.28.23726-r1.ebuild')

diff --git a/dev-libs/intel-compute-runtime/intel-compute-runtime-22.28.23726-r1.ebuild b/dev-libs/intel-compute-runtime/intel-compute-runtime-22.28.23726-r1.ebuild
new file mode 100644
index 000000000000..bdc0a33ff5a4
--- /dev/null
+++ b/dev-libs/intel-compute-runtime/intel-compute-runtime-22.28.23726-r1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_BUILD_TYPE="Release"
+MY_PN="${PN/intel-/}"
+MY_P="${MY_PN}-${PV}"
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Intel Graphics Compute Runtime for oneAPI Level Zero and OpenCL Driver"
+HOMEPAGE="https://github.com/intel/compute-runtime"
+SRC_URI="https://github.com/intel/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+l0 +vaapi"
+
+RDEPEND=">=media-libs/gmmlib-22.1.7:="
+
+DEPEND="
+	${DEPEND}
+	>=dev-libs/intel-metrics-library-0_pre20220526:=
+	dev-libs/libnl:3
+	dev-libs/libxml2:2
+	>=dev-util/intel-graphics-compiler-1.0.11485
+	>=dev-util/intel-graphics-system-controller-0.8.0:=
+	media-libs/mesa
+	>=virtual/opencl-3
+	l0? ( >=dev-libs/level-zero-1.8.1:= )
+	vaapi? (
+		x11-libs/libdrm[video_cards_intel]
+		x11-libs/libva
+	)
+"
+
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( "README.md" "FAQ.md" )
+
+PATCHES=( "${FILESDIR}/${PN}-22.24.23453-remove-fortify-sources.patch" )
+
+src_prepare() {
+	# Remove '-Werror' from default
+	sed -e '/Werror/d' -i CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	# See https://github.com/intel/compute-runtime/issues/531
+	filter-flags -flto=* -flto
+
+	local mycmakeargs=(
+		-DCCACHE_ALLOWED="OFF"
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
+		-DCMAKE_INSTALL_LIBDIR="$(get_libdir)"
+		-DBUILD_WITH_L0="$(usex l0)"
+		-DDISABLE_LIBVA="$(usex !vaapi)"
+		-DNEO__METRICS_LIBRARY_INCLUDE_DIR="${ESYSROOT}/usr/include"
+		-DKHRONOS_GL_HEADERS_DIR="${ESYSROOT}/usr/include"
+		-DOCL_ICD_VENDORDIR="${EPREFIX}/etc/OpenCL/vendors"
+		-DSUPPORT_DG1="ON"
+		-Wno-dev
+
+		# See https://github.com/intel/intel-graphics-compiler/issues/204
+		# -DNEO_DISABLE_BUILTINS_COMPILATION="ON"
+
+		# If enabled, tests are automatically run during
+		# the compile phase and we cannot run them because
+		# they require permissions to access the hardware.
+		-DSKIP_UNIT_TESTS="1"
+	)
+
+	cmake_src_configure
+}
-- 
cgit v1.2.3