From b426a5cef3f0ebe3389686a1c145a834d3a1e120 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 9 Sep 2022 10:40:04 +0100
Subject: gentoo auto-resync : 09:09:2022 - 10:40:04

---
 dev-libs/iniparser/iniparser-3.1-r3.ebuild | 50 ++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 dev-libs/iniparser/iniparser-3.1-r3.ebuild

(limited to 'dev-libs/iniparser/iniparser-3.1-r3.ebuild')

diff --git a/dev-libs/iniparser/iniparser-3.1-r3.ebuild b/dev-libs/iniparser/iniparser-3.1-r3.ebuild
new file mode 100644
index 000000000000..4f0dd7a5229f
--- /dev/null
+++ b/dev-libs/iniparser/iniparser-3.1-r3.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="A free stand-alone ini file parsing library"
+HOMEPAGE="http://ndevilla.free.fr/iniparser/"
+SRC_URI="http://ndevilla.free.fr/iniparser/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc examples"
+# the tests are rather examples than tests, no point in running them
+RESTRICT="test"
+
+BDEPEND="doc? ( app-doc/doxygen )"
+
+S="${WORKDIR}/${PN}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.0b-cpp.patch
+	"${FILESDIR}"/${PN}-3.0-autotools.patch
+	"${FILESDIR}"/${PN}-4.0-out-of-bounds-read.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_install() {
+	if use doc; then
+		emake -C doc
+		HTML_DOCS=( html/. )
+	fi
+
+	default
+
+	if use examples; then
+		docinto examples
+		dodoc test/*.{c,ini,py}
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	# No static archives
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3