From ceeeb463cc1eef97fd62eaee8bf2196ba04bc384 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 29 Feb 2020 18:01:47 +0000
Subject: gentoo (leap year) resync : 29.02.2020

---
 dev-libs/gom/gom-0.4.ebuild | 62 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 dev-libs/gom/gom-0.4.ebuild

(limited to 'dev-libs/gom/gom-0.4.ebuild')

diff --git a/dev-libs/gom/gom-0.4.ebuild b/dev-libs/gom/gom-0.4.ebuild
new file mode 100644
index 000000000000..39a0e11e94df
--- /dev/null
+++ b/dev-libs/gom/gom-0.4.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+GCONF_DEBUG="yes"
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit gnome.org meson python-r1
+
+DESCRIPTION="GObject to SQLite object mapper library"
+HOMEPAGE="https://wiki.gnome.org/Projects/Gom"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="gtk-doc +introspection python test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="python? ( introspection ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=dev-db/sqlite-3.7:3
+	>=dev-libs/glib-2.36:2
+	introspection? ( >=dev-libs/gobject-introspection-1.30.0:= )
+	python? ( ${PYTHON_DEPS}
+		>=dev-python/pygobject-3.16:3[${PYTHON_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	gtk-doc? ( dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3 )
+	virtual/pkgconfig
+	test? ( x11-libs/gdk-pixbuf:2 )
+"
+
+src_prepare() {
+	default
+	sed -i -e '/subdir.*python/d' bindings/meson.build || die
+	# drop test building and deps if not enabled
+	if ! use test; then
+		sed -i -e '/gdkpixbuf_dep/d' meson.build || die
+		sed -i -e '/subdir(.*tests.*)/d' meson.build || die
+	fi
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use introspection enable-introspection)
+		$(meson_use gtk-doc enable-gtk-doc)
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	docinto examples
+	dodoc examples/*.py
+
+	meson_src_install
+
+	if use python; then
+		python_foreach_impl python_domodule bindings/python/gi
+	fi
+}
-- 
cgit v1.2.3