From d0bb3151c569ab6e40c84c177f43bff3c7ce4780 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 25 Aug 2023 15:54:35 +0100
Subject: gentoo auto-resync : 25:08:2023 - 15:54:35

---
 dev-libs/ell/ell-0.58.ebuild | 54 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 dev-libs/ell/ell-0.58.ebuild

(limited to 'dev-libs/ell/ell-0.58.ebuild')

diff --git a/dev-libs/ell/ell-0.58.ebuild b/dev-libs/ell/ell-0.58.ebuild
new file mode 100644
index 000000000000..367a5a212600
--- /dev/null
+++ b/dev-libs/ell/ell-0.58.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic linux-info
+
+DESCRIPTION="Embedded Linux Library provides core, low-level functionality for system daemons"
+HOMEPAGE="https://git.kernel.org/pub/scm/libs/ell/ell.git"
+if [[ "${PV}" == *9999 ]] ; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://git.kernel.org/pub/scm/libs/ell/ell.git"
+else
+	SRC_URI="https://mirrors.edge.kernel.org/pub/linux/libs/${PN}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+LICENSE="LGPL-2.1+"
+SLOT="0"
+
+IUSE="pie test"
+RESTRICT="!test? ( test )"
+
+DEPEND="test? ( sys-apps/dbus )"
+
+CONFIG_CHECK="
+	~TIMERFD
+	~EVENTFD
+	~CRYPTO_USER_API
+	~CRYPTO_USER_API_HASH
+	~CRYPTO_MD5
+	~CRYPTO_SHA1
+	~KEY_DH_OPERATIONS
+"
+
+src_prepare() {
+	default
+	sed -i -e "s#/tmp/ell-test-bus#/tmp/ell-test-bus-$(uuidgen)#" \
+		unit/test-dbus*.c unit/dbus.conf || die
+	[[ "${PV}" == *9999 ]] && eautoreconf
+}
+
+src_configure() {
+	append-cflags "-fsigned-char" #662694
+	local myeconfargs=(
+		$(use_enable pie)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name "*.la" -delete || die
+}
-- 
cgit v1.2.3