From 3cf7c3ef441822c889356fd1812ebf2944a59851 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Tue, 25 Aug 2020 10:45:55 +0100
Subject: gentoo resync : 25.08.2020

---
 dev-libs/cyberjack/cyberjack-3.99.5_p14-r2.ebuild | 90 +++++++++++++++++++++++
 1 file changed, 90 insertions(+)
 create mode 100644 dev-libs/cyberjack/cyberjack-3.99.5_p14-r2.ebuild

(limited to 'dev-libs/cyberjack/cyberjack-3.99.5_p14-r2.ebuild')

diff --git a/dev-libs/cyberjack/cyberjack-3.99.5_p14-r2.ebuild b/dev-libs/cyberjack/cyberjack-3.99.5_p14-r2.ebuild
new file mode 100644
index 000000000000..5ca837df4452
--- /dev/null
+++ b/dev-libs/cyberjack/cyberjack-3.99.5_p14-r2.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN="pcsc-${PN}"
+MY_PV="${PV/_p/final.SP}"
+MY_P="${MY_PN}_${MY_PV}"
+
+inherit autotools flag-o-matic toolchain-funcs udev
+
+DESCRIPTION="REINER SCT cyberJack USB chipcard reader user space driver"
+HOMEPAGE="https://www.reiner-sct.de/"
+SRC_URI="https://support.reiner-sct.de/downloads/LINUX/V${PV/_p/_SP}/${MY_P}.tar.gz -> ${MY_P}.tar.bz2"
+
+KEYWORDS="amd64 x86"
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+IUSE="static-libs threads tools +udev +usb xml"
+
+RDEPEND="
+	sys-apps/pcsc-lite
+	usb? ( virtual/libusb:1 )
+	udev? ( virtual/udev )
+	xml? ( dev-libs/libxml2:2= )
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_P/_/-}"
+
+PATCHES="${FILESDIR}/${P}-gcc10.patch"
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-debug
+		--disable-error-on-warning
+		--disable-hal
+		--disable-mac-universal
+		--disable-mac-arches-i386
+		--disable-mac-arches-x86_64
+		--disable-visibility
+		--enable-pcsc
+		--enable-release
+		--enable-warnings
+		--sysconfdir="/etc/cyberjack"
+		$(use_enable static-libs static)
+		$(use_enable threads)
+		$(use_enable udev)
+		$(use_enable usb nonserial)
+		$(use_enable xml xml2)
+		--with-usbdropdir="$($(tc-getPKG_CONFIG) libpcsclite --variable=usbdropdir)"
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	default
+
+	if use tools; then
+		# cjBingo can't be compiled, as it's defines stuff, which got dropped
+		cd "${S}"/tools/cjflash && emake
+		cd "${S}"/tools/cjgeldkarte && emake
+	fi
+}
+
+src_install() {
+	default
+
+	use tools && dobin tools/cjflash/cjflash tools/cjgeldkarte/cjgeldkarte
+	use udev && udev_newrules "${FILESDIR}"/libifd-cyberjack6.udev-r1 99-cyberjack.rules
+
+	dodoc debian/changelog doc/{LIESMICH,README}.{pdf,txt,xml}
+
+	docinto html
+	dodoc doc/{LIESMICH,README}.html
+
+	docinto source
+	dodoc doc/*.c*
+
+	find "${D}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3