From 39fcd539b9eeb7df75bccad136265b5f001d1a3c Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 16 Dec 2022 15:36:38 +0000
Subject: gentoo auto-resync : 16:12:2022 - 15:36:37

---
 dev-libs/c-blosc/c-blosc-1.21.3.ebuild | 50 ++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 dev-libs/c-blosc/c-blosc-1.21.3.ebuild

(limited to 'dev-libs/c-blosc/c-blosc-1.21.3.ebuild')

diff --git a/dev-libs/c-blosc/c-blosc-1.21.3.ebuild b/dev-libs/c-blosc/c-blosc-1.21.3.ebuild
new file mode 100644
index 000000000000..96e39b39771b
--- /dev/null
+++ b/dev-libs/c-blosc/c-blosc-1.21.3.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Blocking, shuffling and lossless compression library"
+HOMEPAGE="https://www.blosc.org/"
+SRC_URI="
+	https://github.com/Blosc/c-blosc/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0/1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="+lz4 +snappy test zlib zstd"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	lz4? ( >=app-arch/lz4-1.7.5:= )
+	snappy? ( app-arch/snappy:= )
+	zlib? ( sys-libs/zlib:= )
+	zstd? ( app-arch/zstd:= )
+"
+RDEPEND="
+	${DEPEND}
+"
+
+src_configure() {
+	# remove bundled libs (just in case)
+	rm -rf internal-complibs || die
+
+	local mycmakeargs=(
+		-DBUILD_STATIC=OFF
+		-DBUILD_TESTS=$(usex test)
+		-DBUILD_BENCHMARKS=OFF
+		-DBUILD_FUZZERS=OFF
+		-DDEACTIVATE_LZ4=$(usex !lz4)
+		-DDEACTIVATE_SNAPPY=$(usex !snappy)
+		-DDEACTIVATE_ZLIB=$(usex !zlib)
+		-DDEACTIVATE_ZSTD=$(usex !zstd)
+		-DPREFER_EXTERNAL_LZ4=ON
+		# snappy is always external
+		-DPREFER_EXTERNAL_ZLIB=ON
+		-DPREFER_EXTERNAL_ZSTD=ON
+	)
+	cmake_src_configure
+}
-- 
cgit v1.2.3