From 09351e78166b5e864197c4456ebae3f89dd0bed9 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Tue, 22 Jan 2019 10:09:44 +0000
Subject: gentoo resync : 22.01.2019

---
 dev-libs/9libs/9libs-1.0-r4.ebuild | 59 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 dev-libs/9libs/9libs-1.0-r4.ebuild

(limited to 'dev-libs/9libs/9libs-1.0-r4.ebuild')

diff --git a/dev-libs/9libs/9libs-1.0-r4.ebuild b/dev-libs/9libs/9libs-1.0-r4.ebuild
new file mode 100644
index 000000000000..84c7b9323a14
--- /dev/null
+++ b/dev-libs/9libs/9libs-1.0-r4.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools toolchain-funcs
+
+DESCRIPTION="A package of Plan 9 compatibility libraries"
+HOMEPAGE="https://www.netlib.org/research/9libs/9libs-1.0.README"
+SRC_URI="https://www.netlib.org/research/9libs/${P}.tar.bz2"
+
+LICENSE="PLAN9"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="static-libs X"
+
+DEPEND="
+	X? (
+		>=x11-libs/libX11-1.0.0[static-libs?]
+		>=x11-libs/libXt-1.0.0[static-libs?]
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+DOCS=(
+	README
+)
+PATCHES=(
+	"${FILESDIR}"/${PN}-va_list.patch # Bug 385387
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	tc-export CC
+
+	econf \
+		$(use_enable static-libs static) \
+		$(use_with X x) \
+		--enable-shared \
+		--includedir=/usr/include/9libs
+}
+
+src_install() {
+	default
+
+	# rename some man pages to avoid collisions with dev-libs/libevent
+	local f
+	for f in add balloc bitblt cachechars event frame graphics rgbpix; do
+		mv "${D}"/usr/share/man/man3/${f}.{3,3g} || die
+	done
+
+	if ! use static-libs; then
+		find "${ED}" -name '*.la' -delete || die
+	fi
+}
-- 
cgit v1.2.3