From 720452fca3cdf447b4c65bc3bb363032a983309e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 26 May 2023 09:08:49 +0100
Subject: gentoo auto-resync : 26:05:2023 - 09:08:49

---
 dev-lang/vala/vala-0.56.8.ebuild | 48 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 dev-lang/vala/vala-0.56.8.ebuild

(limited to 'dev-lang/vala/vala-0.56.8.ebuild')

diff --git a/dev-lang/vala/vala-0.56.8.ebuild b/dev-lang/vala/vala-0.56.8.ebuild
new file mode 100644
index 000000000000..70072f140f0d
--- /dev/null
+++ b/dev-lang/vala/vala-0.56.8.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2
+
+DESCRIPTION="Compiler for the GObject type system"
+HOMEPAGE="https://wiki.gnome.org/Projects/Vala https://gitlab.gnome.org/GNOME/vala"
+
+LICENSE="LGPL-2.1+"
+SLOT="0.56"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x86-linux"
+IUSE="test valadoc"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.48.0:2
+	>=dev-libs/vala-common-${PV}
+	valadoc? ( >=media-gfx/graphviz-2.16 )
+"
+DEPEND="${RDEPEND}
+	test? (
+		dev-libs/dbus-glib
+		>=dev-libs/glib-2.26:2
+		dev-libs/gobject-introspection
+	)
+"
+BDEPEND="
+	dev-libs/libxslt
+	sys-devel/flex
+	virtual/pkgconfig
+	app-alternatives/yacc
+"
+
+src_configure() {
+	# weasyprint enables generation of PDF from HTML
+	gnome2_src_configure \
+		--disable-unversioned \
+		$(use_enable valadoc) \
+		VALAC=: \
+		WEASYPRINT=:
+}
+
+src_install() {
+	default
+	find "${D}" -name "*.la" -delete || die
+}
-- 
cgit v1.2.3