From e2db47eaae00ec33f8971db44b68645c5d3b9590 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Tue, 17 Aug 2021 11:36:49 +0100
Subject: gentoo resync : 17.08.2021

---
 dev-lang/vala/vala-0.52.5.ebuild | 52 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 dev-lang/vala/vala-0.52.5.ebuild

(limited to 'dev-lang/vala/vala-0.52.5.ebuild')

diff --git a/dev-lang/vala/vala-0.52.5.ebuild b/dev-lang/vala/vala-0.52.5.ebuild
new file mode 100644
index 000000000000..fa44e86dd988
--- /dev/null
+++ b/dev-lang/vala/vala-0.52.5.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome2
+
+DESCRIPTION="Compiler for the GObject type system"
+HOMEPAGE="https://wiki.gnome.org/Projects/Vala"
+
+LICENSE="LGPL-2.1+"
+SLOT="0.52"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x86-linux"
+IUSE="test valadoc"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.48.0:2
+	>=dev-libs/vala-common-${PV}
+	valadoc? ( >=media-gfx/graphviz-2.16 )
+	!<net-libs/libsoup-2.66.2[vala]
+" # Older libsoup generates a libsoup-2.4.vapi that isn't fine for vala:0.46 anymore
+# We block here, so libsoup[vala] consumers wouldn't have to >= it, which would be bad
+# as the newer is not required with older vala when those are picked instead of 0.46.
+# vala-0.45.91 ships a broken libsoup-2.4.vapi copy too, but that'll be fixed by 0.45.92
+DEPEND="${RDEPEND}
+	test? (
+		dev-libs/dbus-glib
+		>=dev-libs/glib-2.26:2
+		dev-libs/gobject-introspection
+	)
+"
+BDEPEND="
+	dev-libs/libxslt
+	sys-devel/flex
+	virtual/pkgconfig
+	virtual/yacc
+"
+
+src_configure() {
+	# weasyprint enables generation of PDF from HTML
+	gnome2_src_configure \
+		--disable-unversioned \
+		$(use_enable valadoc) \
+		VALAC=: \
+		WEASYPRINT=:
+}
+
+src_install() {
+	default
+	find "${D}" -name "*.la" -delete || die
+}
-- 
cgit v1.2.3