From 8376ef56580626e9c0f796d5b85b53a0a1c7d5f5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 14 Jul 2018 21:03:06 +0100
Subject: gentoo resync : 14.07.2018

---
 dev-lang/moarvm/moarvm-9999.ebuild | 61 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 dev-lang/moarvm/moarvm-9999.ebuild

(limited to 'dev-lang/moarvm/moarvm-9999.ebuild')

diff --git a/dev-lang/moarvm/moarvm-9999.ebuild b/dev-lang/moarvm/moarvm-9999.ebuild
new file mode 100644
index 000000000000..f119a7ae28bc
--- /dev/null
+++ b/dev-lang/moarvm/moarvm-9999.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit flag-o-matic
+
+MY_PN="MoarVM"
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/${MY_PN}/${MY_PN}.git"
+	inherit git-r3
+	KEYWORDS=""
+	S="${WORKDIR}/${P}"
+else
+	SRC_URI="http://moarvm.org/releases/${MY_PN}-${PV}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${MY_PN}-${PV}"
+fi
+
+DESCRIPTION="A 6model-based VM for NQP and Rakudo Perl 6"
+HOMEPAGE="http://moarvm.org"
+LICENSE="Artistic-2"
+SLOT="0"
+IUSE="asan clang debug doc +jit static-libs optimize ubsan"
+
+RDEPEND="dev-libs/libatomic_ops
+		>=dev-libs/libtommath-1.0
+		dev-libs/libuv
+		jit? ( dev-lang/lua:0[deprecated]
+			dev-lua/LuaBitOp )
+		virtual/libffi"
+DEPEND="${RDEPEND}
+	clang? ( >=sys-devel/clang-3.1 )
+	dev-lang/perl"
+
+DOCS=( CREDITS README.markdown )
+
+# Tests are conducted via nqp
+RESTRICT=test
+
+src_configure() {
+	use doc && DOCS+=( docs/* )
+	local myconfigargs=(
+		"--prefix=/usr"
+		"--has-libtommath"
+		"--has-libuv"
+		"--has-libatomic_ops"
+		"--has-libffi"
+		"--libdir=$(get_libdir)"
+		"--compiler=$(usex clang clang gcc)"
+		"$(usex asan        --asan)"
+		"$(usex debug       --debug            --no-debug)"
+		"$(usex jit         --lua=/usr/bin/lua --no-jit)"
+		"$(usex optimize    --optimize=        --no-optimize)"
+		"$(usex static-libs --static)"
+		"$(usex ubsan       --ubsan)"
+	)
+	use optimize && filter-flags '-O*'
+
+	perl Configure.pl "${myconfigargs[@]}" || die
+}
-- 
cgit v1.2.3