From 40aaaa64e86ba6710bbeb31c4615a6ce80e75e11 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 28 Apr 2021 20:21:43 +0100
Subject: gentoo resync : 28.04.2021

---
 dev-java/protobuf-java/protobuf-java-3.15.8.ebuild | 56 ++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 dev-java/protobuf-java/protobuf-java-3.15.8.ebuild

(limited to 'dev-java/protobuf-java/protobuf-java-3.15.8.ebuild')

diff --git a/dev-java/protobuf-java/protobuf-java-3.15.8.ebuild b/dev-java/protobuf-java/protobuf-java-3.15.8.ebuild
new file mode 100644
index 000000000000..dfd68dd9ecf0
--- /dev/null
+++ b/dev-java/protobuf-java/protobuf-java-3.15.8.ebuild
@@ -0,0 +1,56 @@
+# Copyright 2008-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/protocolbuffers/protobuf"
+	EGIT_SUBMODULES=()
+fi
+
+DESCRIPTION="Google's Protocol Buffers - Java bindings"
+HOMEPAGE="https://developers.google.com/protocol-buffers/ https://github.com/protocolbuffers/protobuf"
+if [[ "${PV}" == "9999" ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/protocolbuffers/protobuf/archive/v${PV}.tar.gz -> protobuf-${PV}.tar.gz"
+fi
+
+LICENSE="BSD"
+SLOT="0/26"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE=""
+
+BDEPEND="~dev-libs/protobuf-${PV}
+	>=virtual/jdk-1.7"
+DEPEND=">=virtual/jdk-1.7"
+RDEPEND=">=virtual/jre-1.7
+	!<dev-libs/protobuf-3[java(-)]"
+
+S="${WORKDIR}/protobuf-${PV}/java"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_CHECKOUT_DIR="${WORKDIR}/protobuf-${PV}"
+fi
+
+src_prepare() {
+	pushd "${WORKDIR}/protobuf-${PV}" > /dev/null || die
+	eapply_user
+	popd > /dev/null || die
+
+	java-pkg-2_src_prepare
+}
+
+src_compile() {
+	"${BROOT}/usr/bin/protoc" --java_out=core/src/main/java -I../src ../src/google/protobuf/descriptor.proto || die
+	JAVA_SRC_DIR="core/src/main/java" JAVA_JAR_FILENAME="protobuf.jar" java-pkg-simple_src_compile
+}
+
+src_install() {
+	JAVA_SRC_DIR="core/src/main/java" JAVA_JAR_FILENAME="protobuf.jar" java-pkg-simple_src_install
+}
-- 
cgit v1.2.3